zoom_pgd_isba.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE zoom_pgd_isba (CHI, DTCO, DTV, IG, IO, S, K, ISS, UG, U, USS, GCP, &
                                HPROGRAM,HINIFILE,HINIFILETYPE,HFILE,HFILETYPE,OECOCLIMAP)
!     ###########################################################

!!
!!    PURPOSE
!!    -------
!!   This program prepares the physiographic data fields.
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     13/10/03
!!    B. Decharme      2008  XWDRAIN
!!    M.Tomasini    17/04/12  Add interpolation for ISBA variables (MODD_DATA_ISBA_n)
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_ch_isba_n, ONLY : ch_isba_t
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_sso_n, ONLY : sso_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_s_t, isba_k_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_surf_par, ONLY : xundef
USE modd_data_cover_par, ONLY : jpcover
USE modd_isba_par,    ONLY : xoptimgrid
USE modd_prep,           ONLY : cingrid_type, cinterp_type
!
USE modi_get_luout
USE modi_open_aux_io_surf
USE modi_read_surf
USE modi_close_aux_io_surf
USE modi_get_surf_size_n
USE modi_pack_pgd
USE modi_zoom_pgd_isba_full
USE modi_get_aos_n
USE modi_get_sso_n
USE modi_pack_pgd_isba
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
!
TYPE(ch_isba_t), INTENT(INOUT) :: CHI
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_isba_t), INTENT(INOUT) :: DTV
TYPE(grid_t), INTENT(INOUT) :: IG
TYPE(sso_t), INTENT(INOUT) :: ISS
TYPE(isba_options_t), INTENT(INOUT) :: IO
TYPE(isba_s_t), INTENT(INOUT) :: S
TYPE(isba_k_t), INTENT(INOUT) :: K
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
 CHARACTER(LEN=6),     INTENT(IN)  :: HPROGRAM    ! program calling
 CHARACTER(LEN=28),    INTENT(IN)  :: HINIFILE    ! input atmospheric file name
 CHARACTER(LEN=6),     INTENT(IN)  :: HINIFILETYPE! input atmospheric file type
 CHARACTER(LEN=28),    INTENT(IN)  :: HFILE       ! output file name
 CHARACTER(LEN=6),     INTENT(IN)  :: HFILETYPE   ! output file type
LOGICAL,              INTENT(IN)  :: OECOCLIMAP  ! flag to use ecoclimap
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                           :: ISIZE_LMEB_PATCH
INTEGER :: IVERSION, IBUGFIX
INTEGER :: IRESP
INTEGER :: ILUOUT
INTEGER :: IL      ! total 1D dimension (output grid, total surface)
INTEGER :: ILU     ! total 1D dimension (output grid, ISBA points only)
REAL, DIMENSION(:), ALLOCATABLE   :: ZAOSIP    ! A/S i+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZAOSIM    ! A/S i- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZAOSJP    ! A/S j+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZAOSJM    ! A/S j- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZHO2IP    ! h/2 i+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZHO2IM    ! h/2 i- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZHO2JP    ! h/2 j+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZHO2JM    ! h/2 j- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: ZSSO_SLOPE! subgrid slope on all surface points
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('ZOOM_PGD_ISBA',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*      1.     Preparation of IO for reading in the file
!              -----------------------------------------
!
!* Note that all points are read, even those without physical meaning.
!  These points will not be used during the horizontal interpolation step.
!  Their value must be defined as XUNDEF.
!
 CALL open_aux_io_surf(hinifile,hinifiletype,'FULL  ')
!
 CALL read_surf(hinifiletype,'VERSION',iversion,iresp)
 CALL read_surf(hinifiletype,'BUG',ibugfix,iresp) 
 CALL read_surf(hinifiletype,'PATCH_NUMBER',io%NPATCH,iresp)
!
ALLOCATE(io%LMEB_PATCH(io%NPATCH))
!
IF (iversion>=8) THEN
  !
  CALL read_surf(hinifiletype,'MEB_PATCH',io%LMEB_PATCH(:),iresp,hdir='-')
  isize_lmeb_patch = count(io%LMEB_PATCH(:))
  !
  IF (isize_lmeb_patch>0)THEN
    CALL read_surf(hinifiletype,'FORC_MEASURE',io%LFORC_MEASURE,iresp)
    CALL read_surf(hinifiletype,'MEB_LITTER',io%LMEB_LITTER,iresp)
    CALL read_surf(hinifiletype,'MEB_GNDRES',io%LMEB_GNDRES,iresp)
  ELSE      
    io%LFORC_MEASURE = .false.
    io%LMEB_LITTER   = .false.
    io%LMEB_GNDRES   = .false.    
  ENDIF
  !
ELSE
  io%LMEB_PATCH(:)= .false.
  io%LFORC_MEASURE= .false.
  io%LMEB_LITTER  = .false.
  io%LMEB_GNDRES  = .false.
ENDIF
!
!
 CALL read_surf(hinifiletype,'GROUND_LAYER',io%NGROUND_LAYER,iresp)
 CALL read_surf(hinifiletype,'ISBA',io%CISBA,iresp)
IF (iversion >= 7) THEN
  CALL read_surf(hinifiletype,'PEDOTF',io%CPEDOTF,iresp)
ELSE
  io%CPEDOTF = 'CH78'
ENDIF
 CALL read_surf(hinifiletype,'PHOTO',io%CPHOTO,iresp)
!
IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=2) THEN
  !
  CALL read_surf(hinifiletype,'TR_ML',io%LTR_ML,iresp)
  !
ELSE 
  io%LTR_ML = .false.
ENDIF
!
IF(io%CISBA=='DIF') THEN
  ALLOCATE(io%XSOILGRID(io%NGROUND_LAYER))
  io%XSOILGRID=xundef
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=2) THEN
    CALL read_surf(hinifiletype,'SOILGRID',io%XSOILGRID,iresp,hdir='-')
  ELSE
    io%XSOILGRID(1:io%NGROUND_LAYER)=xoptimgrid(1:io%NGROUND_LAYER)
  ENDIF
ELSE
  ALLOCATE(io%XSOILGRID(0))
ENDIF
!
!* number of biomass pools
!
IF (iversion>=6) THEN
  CALL read_surf(hprogram,'NBIOMASS',io%NNBIOMASS,iresp)
ELSE
  SELECT CASE (io%CPHOTO)
    CASE ('AST')
      io%NNBIOMASS = 1
    CASE ('NIT')
      io%NNBIOMASS = 3
    CASE ('NCB')
      io%NNBIOMASS = 6
  END SELECT
ENDIF
!
 CALL close_aux_io_surf(hinifile,hinifiletype)
!
!------------------------------------------------------------------------------
io%LECOCLIMAP = oecoclimap
!
!-------------------------------------------------------------------------------
!
!*    7.      Number of points and packing of general fields
!             ----------------------------------------------
!
!
 CALL get_surf_size_n(dtco, u,'NATURE',ilu)
!
ALLOCATE(s%LCOVER     (jpcover))
ALLOCATE(s%XZS        (ilu))
ALLOCATE(ig%XLAT       (ilu))
ALLOCATE(ig%XLON       (ilu))
ALLOCATE(ig%XMESH_SIZE (ilu))
ALLOCATE(iss%XZ0EFFJPDIR(ilu))
!
 CALL pack_pgd(dtco, u,  hprogram, 'NATURE', ig, s%LCOVER, s%XCOVER, s%XZS  )  
!
!------------------------------------------------------------------------------
!
!*      3.     Reading of sand, clay, runoffb, wdrain and interpolations
!              --------------------------------------------------
!
ALLOCATE(k%XSAND(ilu,io%NGROUND_LAYER))
ALLOCATE(k%XCLAY(ilu,io%NGROUND_LAYER))
ALLOCATE(k%XRUNOFFB(ilu))
ALLOCATE(k%XWDRAIN (ilu))
 CALL zoom_pgd_isba_full(chi, dtco, dtv, ig, io, s, k, ug, u, gcp, &
                         hprogram,hinifile,hinifiletype)
!
!-------------------------------------------------------------------------------
!
!*    8.      Packing of ISBA specific fields
!             -------------------------------
!
 CALL get_surf_size_n(dtco, u, 'FULL  ',il)
!
ALLOCATE(zaosip(il))
ALLOCATE(zaosim(il))
ALLOCATE(zaosjp(il))
ALLOCATE(zaosjm(il))
ALLOCATE(zho2ip(il))
ALLOCATE(zho2im(il))
ALLOCATE(zho2jp(il))
ALLOCATE(zho2jm(il))
ALLOCATE(zsso_slope(il))

 CALL get_aos_n(uss,hprogram,il,zaosip,zaosim,zaosjp,zaosjm,zho2ip,zho2im,zho2jp,zho2jm)
 CALL get_sso_n(uss,hprogram,il,zsso_slope)

 CALL pack_pgd_isba(dtco, ig%NDIM, iss, u, hprogram,              &
                     zaosip, zaosim, zaosjp, zaosjm,              &
                     zho2ip, zho2im, zho2jp, zho2jm,              &
                     zsso_slope                                   )  
!
DEALLOCATE(zaosip)
DEALLOCATE(zaosim)
DEALLOCATE(zaosjp)
DEALLOCATE(zaosjm)
DEALLOCATE(zho2ip)
DEALLOCATE(zho2im)
DEALLOCATE(zho2jp)
DEALLOCATE(zho2jm)
DEALLOCATE(zsso_slope)
IF (lhook) CALL dr_hook('ZOOM_PGD_ISBA',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE zoom_pgd_isba