teb_morpho.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################################################################
      SUBROUTINE teb_morpho(HPROGRAM, T   )
!     ###########################################################################################################
!
!!****  *TEB_MORPHO* 
!!
!!    PURPOSE
!!    -------
!!**** routine to verify and compute the canyon/building morphology in TEB
!!
!!**  METHOD
!!    ------
!! the routine controls the canyon/building morphology
!!    - in the case of low building fraction (lower than 10^-4)
!!    - in the case of high building fraction (higher than 0.9999)
!!    - building height
!!    - in the case of low road fraction
!!    - in the case of low/hight wall surface ratio 
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      G. Pigeon   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2011
!!      C. de Munck and A. lemonsu 05/2013 : - corrections in case of too high WALL_O_HOR (6.)
!!                                           - final check of parameters range added
!----------------------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_teb_n, ONLY : teb_t
!
USE modi_get_luout
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=6),     INTENT(IN)  :: HPROGRAM    ! program calling surf. schemes
!
TYPE(teb_t), INTENT(INOUT) :: T
!
!*       0.2   Declarations of local variables
!
INTEGER :: JJ
INTEGER :: ILUOUT
!
REAL, DIMENSION(SIZE(T%XBLD)) :: ZWALL_O_BLD   ! Initial wall to built surface ratio
REAL, DIMENSION(SIZE(T%XBLD)) :: ZWALL_O_HOR   ! Initial wall to horizontal surface ratio
!
REAL, DIMENSION(2) :: ZRANGE_BLD        = (/ 0.0001  ,   0.9999 /) ! Range allowed for T%XBLD variation
REAL, DIMENSION(2) :: ZRANGE_ROAD       = (/ 0.0001  ,   0.9999 /) ! Range allowed for T%XROAD variation
REAL, DIMENSION(2) :: ZRANGE_BLD_HEIGHT = (/ 3.      , 829.84   /) ! Range allowed for T%XBLD_HEIGHT variation
REAL, DIMENSION(2) :: ZRANGE_WALL_O_HOR = (/ 0.00012 , 322.     /) ! Range allowed for T%XWALL_O_HOR variation
!
!
!*       1.   Get listing file for warnings
!
 CALL get_luout(hprogram, iluout)
!

zwall_o_bld(:) = 0.
zwall_o_hor(:) = 0.

DO jj=1,SIZE(t%XBLD)
   !
   !*    2.   Control building height no lower than 3.m and no higher than 829.84m
   !          reference: http://en.wikipedia.org/wiki/List_of_tallest_buildings_and_structures_in_the_world (2011)
   !          and control Z0_TOWN
   !
   IF (t%XBLD_HEIGHT(jj) < zrange_bld_height(1) ) THEN
      t%XBLD_HEIGHT(jj) = zrange_bld_height(1)
   ENDIF
   IF (t%XBLD_HEIGHT(jj) > zrange_bld_height(2)) &
           CALL abor1_sfx('TEB_MORPHO: T%XBLD_HEIGHT higher than 829.84, highest building in the world, should be lower')
   !
   IF (t%XZ0_TOWN(jj) > t%XBLD_HEIGHT(jj)) THEN
      CALL abor1_sfx('TEB_MORPHO: T%XZ0_TOWN higher than T%XBLD_HEIGHT, should be lower')
   ENDIF
   !
   !*    3.   Control no and almost no building in the cell
   !          authorize building up to 10m and W_O_H 0.001
   !
   IF (t%XBLD(jj) < zrange_bld(1) ) THEN
      t%XBLD(jj) = zrange_bld(1)
      t%XGARDEN(jj) = min(t%XGARDEN(jj), 1.-2.*t%XBLD(jj))
   ENDIF
   !
   !*    4.   Control only building in the cell: could occur for high resolution 
   !          theoretically W_O_H could be 0. -> impose that at least the wall surface is equal to the mesh perimeter x building 
   !          height for a mesh size of 100 x 100m; the waste heat is released at the roof level
   !
   IF (t%XBLD(jj) > zrange_bld(2)) THEN
      t%XBLD(jj) = zrange_bld(2)
      IF (t%XGARDEN(jj) > 0.) THEN
         t%XGARDEN(jj) = 0. 
      ENDIF
   ENDIF
   !
   !*    5.   Control wall surface low respective to building density and building height: pb of the input
   !          Evaluation of the minimum woh is done for mesh size of 1000. m
   !          wall surface of the building evaluated considering 1 square building
   !
   IF (t%XWALL_O_HOR(jj) < 4. * sqrt(t%XBLD(jj))*t%XBLD_HEIGHT(jj)/1000.) THEN
      t%XWALL_O_HOR(jj) = 4. * sqrt(t%XBLD(jj))*t%XBLD_HEIGHT(jj)/1000. 
   ENDIF
   !
   !*    6.   Control facade surface vs building height, case of too high WALL_O_HOR
   !
   t%XWALL_O_BLD(jj) = t%XWALL_O_HOR(jj)/t%XBLD(jj)
   !
   IF (t%XWALL_O_BLD(jj) > (0.4 * t%XBLD_HEIGHT(jj))) THEN ! <=> side_of_building < 10 m
      !     
      zwall_o_hor(jj) = t%XWALL_O_HOR(jj)
      zwall_o_bld(jj) = t%XWALL_O_BLD(jj)
      !
      t%XWALL_O_HOR(jj) = 0.4 * t%XBLD (jj) * t%XBLD_HEIGHT(jj) ! correction WOHOR v2.1
      t%XWALL_O_BLD(jj) = t%XWALL_O_HOR(jj) / t%XBLD       (jj) ! correction WOHOR v2.1

   ENDIF
   !
   !*    7.   Verify road
   !
   t%XROAD      (jj) = 1.-(t%XGARDEN(jj)+t%XBLD(jj))
   IF (t%XROAD(jj) <= zrange_road(1) ) THEN
      t%XROAD(jj) = zrange_road(1)
      t%XGARDEN(jj) = max(t%XGARDEN(jj) - zrange_road(1), 0.)
      IF (t%XH_TRAFFIC(jj) > 0. .OR. t%XLE_TRAFFIC(jj) > 0.) THEN
         t%XH_TRAFFIC(jj)  = 0.
         t%XLE_TRAFFIC(jj) = 0.
      ENDIF
   ENDIF
   !
   !*    8.   Final check of parameters range
   !
   IF ( t%XBLD(jj) < zrange_bld(1) .OR. t%XBLD(jj) > zrange_bld(2) ) THEN
        WRITE(iluout,*) 'WARNING : T%XBLD is still out of range after final corrections &
        &for grid mesh',jj,' : ',t%XBLD(jj)
   ENDIF
   !
   IF ( t%XBLD_HEIGHT(jj) < zrange_bld_height(1) .OR. t%XBLD_HEIGHT(jj) > zrange_bld_height(2) ) THEN
        WRITE(iluout,*) 'WARNING : T%XBLD_HEIGHT is still out of range after final corrections &
        &for grid mesh',jj,' : ',t%XBLD_HEIGHT(jj)
   ENDIF
   !
   IF ( t%XWALL_O_HOR(jj) < zrange_wall_o_hor(1) .OR. t%XWALL_O_HOR(jj) > zrange_wall_o_hor(2) ) THEN
        WRITE(iluout,*) 'WARNING : T%XWALL_O_HOR is still out of range after final corrections &
        &for grid mesh',jj,' : ',t%XWALL_O_HOR(jj)
   ENDIF
   !
   IF ( t%XWALL_O_BLD(jj) - (0.4 * t%XBLD_HEIGHT(jj)) > 10e-16 ) THEN
        WRITE(iluout,*) 'WARNING : T%XWALL_O_BLD is still too high after final corrections &
        &for grid mesh',jj,' : ',t%XWALL_O_BLD(jj)
   ENDIF
   !
ENDDO
!
!
!*    9.   Compute morphometric parameters 
!
t%XCAN_HW_RATIO(:)    = 0.5 * t%XWALL_O_HOR(:) / (1.-t%XBLD(:))
!
!* relative surface fraction
!
t%XROAD_O_GRND(:)   = t%XROAD(:)       / (t%XROAD(:) + t%XGARDEN(:))
t%XGARDEN_O_GRND(:) = t%XGARDEN(:)     / (t%XROAD(:) + t%XGARDEN(:))
t%XWALL_O_GRND(:)   = t%XWALL_O_HOR(:) / (t%XROAD(:) + t%XGARDEN(:))
!
!* Sky-view-factors:
!
t%XSVF_ROAD  (:) = (sqrt(t%XCAN_HW_RATIO(:)**2+1.) - t%XCAN_HW_RATIO(:))
t%XSVF_GARDEN(:) = t%XSVF_ROAD(:)
t%XSVF_WALL  (:) =  0.5*(t%XCAN_HW_RATIO(:)+1.-sqrt(t%XCAN_HW_RATIO(:)**2+1.))/t%XCAN_HW_RATIO(:)
!
END SUBROUTINE teb_morpho