spinup_max.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE spinup_max(PSPINMAX,KNBYEARSPIN,KNBYEARSOLD,KSPIN)
  
!     #######################################################################
!
!
!!****  *SPINUP_MAX*  
!!
!!    PURPOSE
!!    -------
!!    Number of times the accelerated subroutine is called  
!!     
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      R. Alkama           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original      03/26/2012
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_co2v_par,  ONLY : xspin_co2
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL,    INTENT(IN)              :: PSPINMAX  ! max number of times the accelerated subroutine
                                              ! is called for each time step in simulation
                                              ! during the acceleration procedure

INTEGER, INTENT(IN)              :: KNBYEARSPIN ! spinup duration in years
                                                ! nbr of years needed to reach the equilibrium
INTEGER, INTENT(IN)              :: KNBYEARSOLD 
INTEGER, INTENT(OUT)             :: KSPIN        
!                                         
!
!*      0.2    declarations of local variables
!
!We assume that 10% of the spinup period is for ramping up CO2 concentration
!from XCO2_START to XCO2_END
!
REAL, PARAMETER  :: ZSPIN_MAX      = 0.6  ! spin up soil at its maximum PSPINMAX
REAL             :: ZSPIN_DECREASE        ! fraction of KNBYEARSPIN period used to
!
REAL             :: ZSLOPE
REAL             :: ZMAX
REAL             :: ZDECREASE
!
INTEGER          :: IMAX
INTEGER          :: IDECREASE
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!       1.     Initializations
!              ---------------
!
IF (lhook) CALL dr_hook('SPINUP_MAX',0,zhook_handle)
!
zspin_decrease=1.0-zspin_max-xspin_co2
!
zmax = zspin_max*REAL(knbyearspin)
imax = nint(zmax)
!
zdecrease = zmax+zspin_decrease*REAL(knbyearspin)
idecrease = nint(zdecrease)
!
IF ( knbyearsold <= imax)THEN
   !
   kspin = nint(pspinmax)
   !
ELSE IF (knbyearsold > imax .AND. knbyearsold <= idecrease)THEN
   !
   zslope  = (pspinmax-1.0) / (zdecrease - zmax)
   !
   kspin = nint(pspinmax - zslope * (REAL(KNBYEARSOLD) - ZMAX))
   !
   kspin = max(kspin,1)
   !
ELSE
   !
   kspin = 1
   !   
ENDIF
!
IF (lhook) CALL dr_hook('SPINUP_MAX',1,zhook_handle)
!
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE