read_prep_seaflux_conf.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_prep_seaflux_conf (OMERCATOR, HPROGRAM,HVAR,HFILE,HFILETYPE,&
                                         HFILEPGD,HFILEPGDTYPE, HATMFILE,HATMFILETYPE,&
                                         HPGDFILE,HPGDFILETYPE,KLUOUT,OUNIF)
!     #######################################################
!
!!****  *READ_PREP_SEAFLUX_CONF* - routine to read the configuration for 
!!                                 SEAFLUX fields preparation
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      S. Malardel   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!!      P. Le Moigne 10/2005, Phasage Arome
!!      C. Lebeaupin 01/2008  Add oceanic variables initialization
!!      Modified     09/2013  S. Senesi : introduce variables for sea-ice scheme 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_ocean_n, ONLY : ocean_t
!
USE modn_prep_seaflux
!
USE modi_read_prep_surf_atm_conf
USE modi_prep_ocean_mercatorvergrid
!
USE modd_prep_seaflux, ONLY : cfile_seaflx, ctype_seaflx, cfilepgd_seaflx, ctypepgd, &
                              xsst_unif, xsss_unif, xsic_unif
!
USE modd_surf_par,   ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
LOGICAL, INTENT(IN) :: OMERCATOR
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! program calling ISBA
 CHARACTER(LEN=7),  INTENT(IN)  :: HVAR     ! variable treated
 CHARACTER(LEN=28), INTENT(OUT) :: HFILE    ! file name
 CHARACTER(LEN=6),  INTENT(OUT) :: HFILETYPE! file type
 CHARACTER(LEN=28), INTENT(OUT) :: HFILEPGD    ! file name
 CHARACTER(LEN=6),  INTENT(OUT) :: HFILEPGDTYPE! file type
 CHARACTER(LEN=28), INTENT(IN)  :: HATMFILE    ! atmospheric file name
 CHARACTER(LEN=6),  INTENT(IN)  :: HATMFILETYPE! atmospheric file type
 CHARACTER(LEN=28), INTENT(IN)  :: HPGDFILE    ! atmospheric file name
 CHARACTER(LEN=6),  INTENT(IN)  :: HPGDFILETYPE! atmospheric file type
INTEGER,           INTENT(IN)  :: KLUOUT   ! logical unit of output listing
LOGICAL,           INTENT(OUT) :: OUNIF    ! flag for prescribed uniform field

!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: IRESP          ! IRESP  : return-code if a problem appears 
                                    ! at the open of the file in LFI  routines 
INTEGER           :: ILUNAM         ! Logical unit of namelist file
!
 CHARACTER(LEN=28) :: YNAMELIST      ! namelist file
!
LOGICAL           :: GFOUND         ! Return code when searching namelist
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('READ_PREP_SEAFLUX_CONF',0,zhook_handle)
hfile = '                         '
hfiletype = '      '
!
hfilepgd = '                            '
hfilepgdtype = '      '
!
ounif     = .false.
!
!-------------------------------------------------------------------------------
!
!* Select seaflux files if they are defined
!  -----------------------------------------
!
IF (len_trim(hfile)==0 .AND. len_trim(cfile_seaflx)>0 .AND. len_trim(ctype_seaflx)>0) THEN
  hfile     = cfile_seaflx
  hfiletype = ctype_seaflx
END IF
!
IF (len_trim(hfilepgd)==0 .AND. len_trim(cfilepgd_seaflx)>0 .AND. len_trim(ctypepgd)>0) THEN
  hfilepgd     = cfilepgd_seaflx
  hfilepgdtype = ctypepgd
END IF
!
!! If no file name in the scheme namelist,
!! try to find a name in NAM_SURF_ATM
!
IF (len_trim(hfile)==0) THEN
!
 CALL read_prep_surf_atm_conf(hprogram,hfile,hfiletype,hfilepgd,hfilepgdtype,&
                             hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kluout)
!
END IF
!-------------------------------------------------------------------------------
!
!* Is an uniform field prescribed?
!  ------------------------------
!
SELECT CASE (hvar)
   CASE ('SST    ') 
      ounif = (xsst_unif/=xundef) 
   CASE ('SSS    ') 
      IF (cseaice_scheme == 'NONE  '.AND. &
         len_trim(hfiletype)==0.0   .AND. &
         xsss_unif==xundef                )THEN
         xsss_unif=0.0
      ENDIF
      ounif = (xsss_unif/=xundef)
   CASE ('SIC    ') 
      ounif = (xsic_unif/=xundef) 
END SELECT

!
!-------------------------------------------------------------------------------
!
!* If no file and no uniform field is prescribed: error
!  ---------------------------------------------
!
IF (hvar=='DATE   ' .OR. hvar=='ZS     ') THEN
  ounif = (hfiletype=='      ')
  IF (lhook) CALL dr_hook('READ_PREP_SEAFLUX_CONF',1,zhook_handle)
  RETURN
END IF
!
IF (len_trim(hfiletype)==0 .AND. .NOT. ounif) THEN
   CALL abor1_sfx('READ_PREP_SEAFLUX_CONF: AN INPUT VALUE IS REQUIRED FOR '//hvar)
END IF
!
!-------------------------------------------------------------------------------
!
!* If 1D coupling: ocean variables initializing
!  --------------------------------------------
!
IF (omercator) THEN
  WRITE(kluout,*) 'LMERCATOR=T : initializing oceanic vertical grid'
  CALL prep_ocean_mercatorvergrid(hprogram,ounif)
END IF
IF (lhook) CALL dr_hook('READ_PREP_SEAFLUX_CONF',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_prep_seaflux_conf