prep_teb_greenroof_ascllv.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_teb_greenroof_ascllv (DTCO, UG, U, USS, &
                                      HPROGRAM,HSURF,KLUOUT,PFIELD)
!     #################################################################################
!
!!****  *PREP_TEB_GREENROOF_ASCLLV* - prepares ISBA field from prescribed values
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    Based on "prep_teb_garden_ASCLLV"
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!    A. Lemonsu & C. de Munck 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2011
!!------------------------------------------------------------------
!
!
!
!
USE modd_surfex_mpi, ONLY : nproc, nindex, nnum, ncomm, npio, nrank
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_prep,              ONLY : cinterp_type
USE modd_pgd_grid,          ONLY : nl,llatlonmask,cgrid,xgrid_par,ngrid_par
USE modd_pgdwork,           ONLY : catype
USE modd_data_cover_par,    ONLY : nvegtype
USE modd_surf_par,          ONLY : xundef
USE modd_prep_teb_greenroof,ONLY : ctype_hug     , ctype_tg     , &
                                   cfile_hug_surf_gr, cfile_tg_surf_gr, &
                                   cfile_hug_root_gr, cfile_tg_root_gr, &
                                   cfile_hug_deep_gr, cfile_tg_deep_gr  
USE modi_pgd_field
USE modi_get_latlonmask_n
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: HSURF     ! type of field
INTEGER,            INTENT(IN)  :: KLUOUT    ! logical unit of output listing
REAL, POINTER, DIMENSION(:,:,:) :: PFIELD    ! field to interpolate horizontally
!
!*      0.2    declarations of local variables
!
INTEGER :: JV ! loop counter
INTEGER :: JLAYER
INTEGER :: IL
!
INTEGER, DIMENSION(0:NPROC-1) :: INB
INTEGER :: INFOMPI, JJ
!
REAL, ALLOCATABLE, DIMENSION(:,:)     :: ZFIELD
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_TEB_GREENROOF_ASCLLV',0,zhook_handle)
!
IF (.NOT.ALLOCATED(nnum)) THEN
  ALLOCATE(nnum(u%NDIM_FULL))
  IF (nrank/=npio) THEN
    IF (ALLOCATED(nindex)) DEALLOCATE(nindex)
    ALLOCATE(nindex(u%NDIM_FULL))
  ENDIF  
  IF (nrank==npio) THEN
    inb(:) = 0
    DO jj=1,u%NDIM_FULL
      inb(nindex(jj)) = inb(nindex(jj))+1
      nnum(jj) = inb(nindex(jj))
    ENDDO
  ENDIF
  IF (nproc>1) THEN
#ifdef SFX_MPI          
    CALL mpi_bcast(nindex,SIZE(nindex)*kind(nindex)/4,mpi_integer,npio,ncomm,infompi)
    CALL mpi_bcast(nnum,SIZE(nnum)*kind(nnum)/4,mpi_integer,npio,ncomm,infompi)
    CALL mpi_bcast(ug%NGRID_FULL_PAR,kind(ug%NGRID_FULL_PAR)/4,mpi_integer,npio,ncomm,infompi)
#endif
    IF (nrank/=npio) ALLOCATE(ug%XGRID_FULL_PAR(ug%NGRID_FULL_PAR))
#ifdef SFX_MPI    
    CALL mpi_bcast(ug%XGRID_FULL_PAR,&
      SIZE(ug%XGRID_FULL_PAR)*kind(ug%XGRID_FULL_PAR)/4,mpi_real,npio,ncomm,infompi)    
#endif
  ENDIF
ENDIF
!
catype = 'ARI'
!
!*      1.    get full dimension of grid
!
 CALL get_type_dim_n(dtco, u, &
                     'FULL  ',nl)
!
!*      2.    get nature dimension
!
 CALL get_type_dim_n(dtco, u, &
                     'TOWN  ',il)
!
ALLOCATE(zfield(il,3))
!
!*      3.    get grid informations known over full grid
!
 CALL get_latlonmask_n(ug, &
                       llatlonmask,cgrid,xgrid_par,ngrid_par)
!
!
SELECT CASE(hsurf)
!
!
!*      4.    Profile of soil relative humidity
!
  CASE('WG     ')

    CALL pgd_field(dtco, ug, u, uss, &
                   hprogram,'HUG_SURF: relative humidity','TWN',cfile_hug_surf_gr,   &
                        ctype_hug,xundef,zfield(:,1))  
    CALL pgd_field(dtco, ug, u, uss, &
                   hprogram,'HUG_ROOT: relative humidity','TWN',cfile_hug_root_gr,   &
                        ctype_hug,xundef,zfield(:,2))  
    CALL pgd_field(dtco, ug, u, uss, &
                   hprogram,'HUG_DEEP: relative humidity','TWN',cfile_hug_deep_gr,   &
                        ctype_hug,xundef,zfield(:,3))  

    ALLOCATE(pfield(il,3,nvegtype))
    DO jv=1,nvegtype
      pfield(:,1,jv) = zfield(:,1)
      pfield(:,2,jv) = zfield(:,2)
      pfield(:,3,jv) = zfield(:,3)
    END DO

!*      5.    Profile of temperatures

  CASE('TG     ')

    CALL pgd_field(dtco, ug, u, uss, &
                   hprogram,'TG_SURF: temperature','TWN',cfile_tg_surf_gr,   &
                        ctype_tg,xundef,zfield(:,1))  
    CALL pgd_field(dtco, ug, u, uss, &
                   hprogram,'TG_ROOT: temperature','TWN',cfile_tg_root_gr,   &
                        ctype_tg,xundef,zfield(:,2))  
    CALL pgd_field(dtco, ug, u, uss, &
                   hprogram,'TG_DEEP: temperature','TWN',cfile_tg_deep_gr,   &
                        ctype_tg,xundef,zfield(:,3))  

    ALLOCATE(pfield(il,3,nvegtype))
    DO jv=1,nvegtype
      pfield(:,1,jv) = zfield(:,1)
      pfield(:,2,jv) = zfield(:,2)
      pfield(:,3,jv) = zfield(:,3)
    END DO

END SELECT
!
!*      6.     Interpolation method
!              --------------------
!
cinterp_type='NONE  '
DEALLOCATE(zfield)
!
DEALLOCATE(nnum)
IF (nrank/=npio) THEN
  DEALLOCATE(nindex,ug%XGRID_FULL_PAR)
  ALLOCATE(nindex(0))
ENDIF
!
IF (lhook) CALL dr_hook('PREP_TEB_GREENROOF_ASCLLV',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_teb_greenroof_ascllv