prep_grid_lonlat_reg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE prep_grid_lonlat_reg (HFILETYPE,HINTERP_TYPE,KNI)
!     ##########################################################################
!
!!****  *PREP_GRID_LATLON* - reads EXTERNALIZED Surface grid.
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      V. Masson
!!
!!    MODIFICATIONS
!!    -------------
!!      Original   06/2003
!-------------------------------------------------------------------------------
!
!*      0. DECLARATIONS
!          ------------
!
!
!
!
USE modi_read_surf
!
USE modd_grid_latlonregul, ONLY : xilat1,xilon1,xilat2,xilon2,ninlat,ninlon,nilength,xilatarray
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!* 0.1. Declaration of arguments
!       ------------------------
!
!
!
 CHARACTER(LEN=6),  INTENT(IN)    :: HFILETYPE    ! file type
 CHARACTER(LEN=6),  INTENT(OUT)   :: HINTERP_TYPE ! Grid type
INTEGER,           INTENT(OUT)   :: KNI          ! number of points
!
!* 0.2 Declaration of local variables
!      ------------------------------
!
 CHARACTER(LEN=12) :: YRECFM    ! Name of the article to be read
INTEGER           :: IRESP
!
INTEGER :: JL        ! loop counter
INTEGER :: ILON
REAL :: ZDLAT, ZDLON
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-----------------------------------------------------------------------
!
!*   1 Projection
!      ----------
!
IF (lhook) CALL dr_hook('PREP_GRID_LONLAT_REG',0,zhook_handle)
yrecfm = 'LONMIN'
 CALL read_surf(hfiletype,yrecfm,xilon1,iresp)
yrecfm = 'LONMAX'
 CALL read_surf(hfiletype,yrecfm,xilon2,iresp)
yrecfm = 'LATMIN'
 CALL read_surf(hfiletype,yrecfm,xilat1,iresp)
yrecfm = 'LATMAX'
 CALL read_surf(hfiletype,yrecfm,xilat2,iresp)
yrecfm = 'NLAT'
 CALL read_surf(hfiletype,yrecfm,ninlat,iresp)
!
IF (ALLOCATED(ninlon)) DEALLOCATE(ninlon)
ALLOCATE(ninlon(ninlat))
yrecfm = 'NLON'
 CALL read_surf(hfiletype,yrecfm,ninlon(1),iresp)
IF (ninlat.GT.1) ninlon(2:ninlat) = ninlon(1)
!
!-----------------------------------------------------------------------
!
!*   3 Computes additional quantities used in interpolation
!      ----------------------------------------------------
!
nilength = ninlat*ninlon(1)
kni = nilength
!
zdlat = (xilat2-xilat1)/ninlat
zdlon = (xilon2-xilon1)/ninlon(1)
!
xilon1 = xilon1 + zdlon/2.
xilon2 = xilon2 - zdlon/2.
xilat1 = xilat1 + zdlat/2.
xilat2 = xilat2 - zdlat/2.
!
IF (ALLOCATED(xilatarray)) DEALLOCATE(xilatarray)
ALLOCATE(xilatarray(ninlat))
!
xilatarray(1)=xilat1
DO jl = 2,ninlat
  xilatarray(jl) = xilatarray(jl-1) + zdlat
ENDDO
!
!-----------------------------------------------------------------------
IF(kni==1)THEN
  hinterp_type = 'UNIF'
ELSE
  hinterp_type = 'HORIBL'
ENDIF
!
IF (lhook) CALL dr_hook('PREP_GRID_LONLAT_REG',1,zhook_handle)
!-----------------------------------------------------------------------
!
END SUBROUTINE prep_grid_lonlat_reg