mxmn_mf.F

Go to the documentation of this file.

      SUBROUTINE mxmn_mf (PARRAY,KLEN,PMAX,PMIN)
      USE parkind1, ONLY : jprb
      USE yomhook , ONLY : lhook, dr_hook
      USE lfi_precision
!
!*******************************************************************
!*
!*    NAME      : MXMN
!*
!*    FUNCTION  : RETURN MAXIMUM AND MINIMUM VALUES FROM AN ARRAY
!*                OF FLOATING POINT NUMBERS.
!*
!*    INPUT     : PARRAY - ARRAY OF NUMBERS
!*                KLEN   - LAST WORD OF THIS ARRAY
!*
!*    OUTPUT    : PMAX - MAXIMUM VALUE
!*                PMIN - MINIMUM VALUE
!*
!*
!*     JOHN HENNESSY, ECMWF, 22 APRIL 1985
!*
!*    Modified by Jean CLOCHARD, French DMN, January 1990.
!*    R. El Khatib 2004-10-12 MAXVAL,MINVAL
!*    F. Vana + NEC Apr-2009: OpenMP
!*
!*******************************************************************
!
      USE oml_mod , ONLY : oml_my_thread , oml_get_num_threads
!
      IMPLICIT NONE
!
      INTEGER (KIND=JPLIKM) :: KLEN
      REAL (KIND=JPDBLD) :: PMAX
      REAL (KIND=JPDBLD) :: PMIN
      REAL (KIND=JPDBLD) :: PARRAY (klen)
      INTEGER (KIND=JPLIKM) :: START, END, BLOCKS, MY_THREAD, THREADS
      REAL (KIND=JPDBLD) :: PMAX_LOCAL, PMIN_LOCAL
!
      REAL(KIND=JPRB) :: ZHOOK_HANDLE
      IF (lhook) CALL dr_hook('MXMN_MF',0,zhook_handle)
      pmax = -huge(parray)
      pmin = huge(parray)
!$OMP PARALLEL                                                          &
!$OMP&PRIVATE(START,END,BLOCKS,MY_THREAD,THREADS,PMAX_LOCAL,PMIN_LOCAL)
      my_thread = oml_my_thread() - 1
      threads = oml_get_num_threads()
      blocks = (klen + threads) / threads
      start = my_thread * blocks + 1
      END = MIN(START+BLOCKS-1,KLEN)
      pmax_local = maxval(parray(start:end))
      pmin_local = minval(parray(start:end))
!$OMP CRITICAL
      pmax = max(pmax,pmax_local)
      pmin = min(pmin,pmin_local)
!$OMP END CRITICAL
!$OMP END PARALLEL

! Avoid +/- 0
  
      IF (abs(pmax) == 0.) pmax = 0.
      IF (abs(pmin) == 0.) pmin = 0.

      IF (lhook) CALL dr_hook('MXMN_MF',1,zhook_handle)
      ENDSUBROUTINE mxmn_mf