minzs_vert_shift.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE minzs_vert_shift(D, PZS_MOY, PZS_MIN, PPS_MIN, PRHOA_2M_MIN  )  
!      #########################################
!
!
!!****   *MINZS_VERT_SHIFT* - routine to shift 2m variables to 2m variables 
!!                            above the minimum orography of the grid mesh
!!
!!
!!     PURPOSE
!!     -------
!
!!**   METHOD
!!     ------
!!
!!     Same method like in forcing_vert_shift.F90
!!
!!     EXTERNAL
!!     --------
!!
!!       NONE
!!
!!     IMPLICIT ARGUMENTS
!!     ------------------
!!
!!     REFERENCE
!!     ---------
!!
!!     AUTHOR
!!     ------
!!       B. Decharme
!! 
!!     MODIFICATIONS
!!     -------------
!!       Original        06/2013
!! ---------------------------------------------------------------------
!
!*       0. DECLARATIONS
!
USE modd_diag_n, ONLY : diag_t
!
USE modd_csts,    ONLY : xrd, xg, xrv
USE modd_atm_cst, ONLY : xclim_t_grad
!
USE mode_thermos
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!
!*       0.1 declarations of arguments
!
TYPE(diag_t), INTENT(INOUT) :: D
!
REAL,    DIMENSION(:), INTENT(IN)  :: PZS_MOY    ! mean orography of atmospheric grid
REAL,    DIMENSION(:), INTENT(IN)  :: PZS_MIN    ! min orography of atmospheric grid
!
REAL,    DIMENSION(:), INTENT(OUT) :: PPS_MIN    ! pressure    at surface     altitude
REAL,    DIMENSION(:), INTENT(OUT) :: PRHOA_2M_MIN  ! density     at surface     altitude
!
!*       0.2 declarations of local variables
!
REAL, DIMENSION(SIZE(D%XQ2M  )) :: ZQA_2M       ! air humidity (kg/kg)
REAL, DIMENSION(SIZE(D%XQ2M  )) :: ZQA_2M_MIN   ! air humidity (kg/kg)
REAL, DIMENSION(SIZE(D%XRHOA)) :: ZRHOA_2M     ! approximated density
REAL, DIMENSION(SIZE(D%XRHOA)) :: ZRHOA_2M_MIN ! approximated density
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
! ---------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MINZS_VERT_SHIFT',0,zhook_handle)
!
zqa_2m = d%XQ2M / d%XRHOA
!
!*       1.  climatological gradient for temperature
!            ---------------------------------------
!
d%XT2M_MIN_ZS = d%XT2M + xclim_t_grad * (pzs_min - pzs_moy)
!
!-------------------------------------------------------------------------------
!
!*       2.  hydrostatism for pressure
!            -------------------------
!
pps_min = d%XPS * exp( - xg/xrd/(0.5*(d%XT2M+d%XT2M_MIN_ZS)*( 1.+((xrv/xrd)-1.)*zqa_2m(:) )) &
                              * (pzs_min-pzs_moy)                                              )  
!
!-------------------------------------------------------------------------------
!
!*       3.  conservation of relative humidity for humidity
!            ----------------------------------------------
!
zqa_2m_min = zqa_2m / qsat(d%XT2M, d%XPS) * qsat(d%XT2M_MIN_ZS,pps_min)
!
!-------------------------------------------------------------------------------
!
!*       4.  estimation of air density from temperature and humidity
!            -------------------------------------------------------
!
zrhoa_2m(:) = d%XPS (:) / xrd /  d%XT2M       (:) / ( 1.+((xrv/xrd)-1.)*zqa_2m(:) )
zrhoa_2m_min(:) = pps_min(:) / xrd /  d%XT2M_MIN_ZS(:) / ( 1.+((xrv/xrd)-1.)*zqa_2m_min(:) )
!
prhoa_2m_min(:) = d%XRHOA(:) * zrhoa_2m_min(:) / zrhoa_2m(:)
!
!-------------------------------------------------------------------------------
!
!*       5.  new humidity in kg/m3
!            ---------------------
!
d%XQ2M_MIN_ZS = zqa_2m_min * prhoa_2m_min
!
IF (lhook) CALL dr_hook('MINZS_VERT_SHIFT',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE minzs_vert_shift