init_isba_mixpar.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE init_isba_mixpar (DTCO, DTV, KDIM, IO, &
                                   KDECADE,KDECADE2,PCOVER,OCOVER,HSFTYPE)
!     ##############################################################
!
!!**** *INIT_ISBA_MIXPAR* 
!!
!!    PURPOSE
!!    -------
!!   This routine makes pre-calculations relative to dependances between
!!    parameters. 
!! 
!!    METHOD
!!    ------
!!   First are treated parameters varying in time. Then, other ones. 
!!   * XPAR_VEGTYPE is needed as soon as 1 LDATA_ is true to use av_pgd_param. 
!!   * XPAR_LAI is needed as soon as av_pgd_param is called with YLAI
!!   * XPAR_VEG is needed as soon as av_pgd_param is called with YVEG
!!   * XPAR_H_TREE is needed as soon as Z0 is calculated by ini_data_param by point
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    16/11/10
!!    P. Samuelsson  10/2014  MEB
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_isba_options_n, ONLY : isba_options_t
!
USE modd_type_date_surf
USE modd_surf_par,       ONLY : xundef
USE modd_data_cover_par, ONLY : nvegtype, nvegtype_old, nvegtype_ecosg
!
!
USE modd_data_cover,     ONLY : xdata_lai, xdata_h_tree, xdata_veg,         &
                                xdata_irrig, xdata_watsup, tdata_seed,      &
                                tdata_reap
!     
USE modi_ini_data_param
USE modi_av_pgd
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_isba_t), INTENT(INOUT) :: DTV
INTEGER, INTENT(IN) :: KDIM
TYPE(isba_options_t), INTENT(INOUT) :: IO
!
INTEGER,                INTENT(IN)    :: KDECADE
INTEGER,                INTENT(OUT)   :: KDECADE2
REAL, DIMENSION(:,:),   INTENT(IN)    :: PCOVER
LOGICAL, DIMENSION(:),  INTENT(IN)    :: OCOVER
 CHARACTER(LEN=*),       INTENT(IN)    :: HSFTYPE ! nature / garden
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
TYPE(date_time), DIMENSION(:,:), ALLOCATABLE :: TPWORK
REAL, DIMENSION(NVEGTYPE)   :: XSTRESS   ! 1. if defensive /0. if offensive
REAL, DIMENSION(NVEGTYPE)   :: XSTRESS_NOAGRI   ! 1. if defensive /0. if offensive
!
 CHARACTER(LEN=3)  :: YTREE, YNAT, YVEG
!
INTEGER               :: JVEG, JT, ji
!
INTEGER               :: ISIZE_LMEB_PATCH  ! Number of patches with MEB=true
!
!*    0.3    Declaration of namelists
!            ------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('INIT_ISBA_MIXPAR',0,zhook_handle)
!
IF (nvegtype==nvegtype_ecosg) THEN
  xstress        = (/1.,1.,1.,0.,0.,0.,0.,0.,1.,1.,1.,0.,0.,0.,0.,1.,1.,0.,0.,0./)
  xstress_noagri = (/1.,1.,1.,0.,0.,0.,0.,0.,1.,1.,1.,0.,0.,0.,0.,0.,0.,0.,0.,0./)
ELSE
  xstress =        (/1.,1.,1.,0.,1.,0.,1.,0.,1.,0.,0.,0.,0.,0.,1.,0.,1.,0.,0./)
  xstress_noagri = (/1.,1.,1.,0.,1.,0.,0.,0.,0.,0.,0.,0.,0.,0.,1.,0.,1.,0.,0./)
ENDIF
!
isize_lmeb_patch=count(io%LMEB_PATCH(:))
!
IF (.NOT.dtv%LDATA_MIXPAR) THEN
  IF (lhook) CALL dr_hook('INIT_ISBA_MIXPAR',1,zhook_handle)
  RETURN
ENDIF
!
IF (hsftype=='NAT') THEN
  ynat='NAT'
  ytree='TRE'
  yveg='VEG'
ELSEIF (hsftype=='GRD') THEN
  ynat='GRD'
  ytree='GRT'
  yveg='GRV'
ENDIF
!
kdecade2 = kdecade
IF (dtv%NTIME==2) kdecade2 = kdecade2 + 10 
kdecade2 = (kdecade2-1) * dtv%NTIME / 36 + 1
IF (dtv%NTIME==2 .AND. kdecade2==3) kdecade2 = 1
!
!          1. Arrays needed further
!          ------------------------
!
!XPAR_VEGTYPE will be needed to use ini_data_param by point
IF (.NOT.dtv%LDATA_VEGTYPE) THEN
  ALLOCATE(dtv%XPAR_VEGTYPE   (kdim,nvegtype))
  DO jveg=1,nvegtype
    CALL av_pgd(dtco,dtv%XPAR_VEGTYPE(:,jveg),pcover ,dtco%XDATA_VEGTYPE(:,jveg),ynat,'ARI',ocover)
  END DO
  !DTV%XPAR_VEGTYPE(:,:)=DTV%XPAR_VEGTYPE(:,:)/SPREAD(SUM(DTV%XPAR_VEGTYPE(:,:),2),2,NVEGTYPE)
ENDIF
!
!xpar_lai: needed for av_pgd_param with YLAI
IF (.NOT.any(dtv%LDATA_LAI)) THEN
  ALLOCATE(dtv%XPAR_LAI(kdim,dtv%NTIME,nvegtype))
  CALL av_pgd(dtco,dtv%XPAR_LAI(:,kdecade2,:),pcover,xdata_lai(:,kdecade,:),yveg,'ARI',ocover,kdecade=kdecade)
ENDIF
!
!veg
IF (.NOT.any(dtv%LDATA_VEG)) THEN
  ALLOCATE(dtv%XPAR_VEG(kdim,dtv%NTIME,nvegtype))
  IF (any(dtv%LDATA_LAI)) THEN
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,plai=dtv%XPAR_LAI,pveg_out=dtv%XPAR_VEG)
    dtv%LDATA_VEG(:)=.true.
  ELSE
    CALL av_pgd(dtco,dtv%XPAR_VEG(:,kdecade2,:),pcover,xdata_veg(:,kdecade,:),ynat,'ARI',ocover,kdecade=kdecade)
  ENDIF
ENDIF
!
!ht: needed to calculate z0, if not calculated yet during extrapolation 
IF (.NOT.any(dtv%LDATA_H_TREE) .AND. .NOT.any(dtv%LDATA_Z0) .AND. any(dtv%LDATA_LAI)) THEN
  ALLOCATE(dtv%XPAR_H_TREE(kdim,nvegtype))
  CALL av_pgd(dtco,dtv%XPAR_H_TREE,pcover,xdata_h_tree,ytree,'ARI',ocover,kdecade=kdecade)
  dtv%LDATA_H_TREE(:) = .true.
ENDIF
!
!dg: initialization for ROOTFRAC
!ROOTFRAC depends on ROOT_DEPTH, DG, ROOT_EXT, ROOT_LIN
IF (.NOT.any(dtv%LDATA_ROOTFRAC) .AND. io%CISBA=='DIF' .AND. any(dtv%LDATA_ROOT_DEPTH)) THEN
  !
  IF (.NOT.any(dtv%LDATA_ROOT_EXTINCTION)) THEN
    ALLOCATE(dtv%XPAR_ROOT_EXTINCTION(kdim,nvegtype))
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,proot_extinction=dtv%XPAR_ROOT_EXTINCTION)
    dtv%LDATA_ROOT_EXTINCTION(:) = .true.
  ENDIF
  !
  IF (.NOT.any(dtv%LDATA_ROOT_LIN)) THEN
    ALLOCATE(dtv%XPAR_ROOT_LIN(kdim,nvegtype))
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,proot_lin=dtv%XPAR_ROOT_LIN)
    dtv%LDATA_ROOT_LIN(:) = .true.
  ENDIF
  !
ENDIF
!
!dice: depth of the soil column for the calculation of the frozen soil fraction (m)
IF (any(dtv%LDATA_DG) .AND. .NOT.any(dtv%LDATA_DICE)) THEN
  !
  ALLOCATE(dtv%XPAR_DICE(kdim,nvegtype))
  !
  IF(io%CISBA/='DIF')THEN
    dtv%XPAR_DICE(:,:)=max(0.2,0.8*dtv%XPAR_DG(:,2,:))
    dtv%LDATA_DICE(:)=.true.
  ENDIF
!
ENDIF
!
!          2. Calculations of parameters dependant on others
!          -------------------------------------------------
!
!emis
IF (.NOT.any(dtv%LDATA_EMIS) .AND. any(dtv%LDATA_VEG)) THEN
  ALLOCATE(dtv%XPAR_EMIS(kdim,dtv%NTIME,nvegtype))
  CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pveg_in=dtv%XPAR_VEG,pemis_eco=dtv%XPAR_EMIS)
  dtv%LDATA_EMIS(:)=.true.
ENDIF
!z0
IF (.NOT.any(dtv%LDATA_Z0) .AND. (any(dtv%LDATA_LAI) .OR.any(dtv%LDATA_H_TREE))) THEN
  ALLOCATE(dtv%XPAR_Z0(kdim,dtv%NTIME,nvegtype))
  CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,plai=dtv%XPAR_LAI,ph_tree=dtv%XPAR_H_TREE,pz0=dtv%XPAR_Z0)
  dtv%LDATA_Z0(:)=.true.
ENDIF

!RSMIN
IF (any(dtv%LDATA_LAI)) THEN
  IF (.NOT.any(dtv%LDATA_RSMIN)) THEN
    ALLOCATE(dtv%XPAR_RSMIN(kdim,nvegtype))
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,prsmin=dtv%XPAR_RSMIN)
  ENDIF
  dtv%LDATA_RSMIN(:)=.true.
ENDIF

!parameters calculated on veg fraction
IF (any(dtv%LDATA_VEG)) THEN
  !
  IF (.NOT.any(dtv%LDATA_GAMMA))      ALLOCATE(dtv%XPAR_GAMMA     (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_WRMAX_CF))   ALLOCATE(dtv%XPAR_WRMAX_CF  (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_RGL))        ALLOCATE(dtv%XPAR_RGL       (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_CV))         ALLOCATE(dtv%XPAR_CV        (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_ALBNIR_VEG)) ALLOCATE(dtv%XPAR_ALBNIR_VEG(kdim,dtv%NTIME,nvegtype))
  IF (.NOT.any(dtv%LDATA_ALBVIS_VEG)) ALLOCATE(dtv%XPAR_ALBVIS_VEG(kdim,dtv%NTIME,nvegtype))
  IF (.NOT.any(dtv%LDATA_ALBUV_VEG))  ALLOCATE(dtv%XPAR_ALBUV_VEG (kdim,dtv%NTIME,nvegtype))
  IF (.NOT.any(dtv%LDATA_GMES))       ALLOCATE(dtv%XPAR_GMES      (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_BSLAI))      ALLOCATE(dtv%XPAR_BSLAI     (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_SEFOLD))     ALLOCATE(dtv%XPAR_SEFOLD    (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_GC))         ALLOCATE(dtv%XPAR_GC        (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_LAIMIN))     ALLOCATE(dtv%XPAR_LAIMIN    (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_F2I))        ALLOCATE(dtv%XPAR_F2I       (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_CE_NITRO))   ALLOCATE(dtv%XPAR_CE_NITRO  (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_CF_NITRO))   ALLOCATE(dtv%XPAR_CF_NITRO  (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_CNA_NITRO))  ALLOCATE(dtv%XPAR_CNA_NITRO (kdim,nvegtype))
  !
  IF (.NOT.any(dtv%LDATA_GAMMA)) &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pgamma=dtv%XPAR_GAMMA)
  IF (.NOT.any(dtv%LDATA_WRMAX_CF)) &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pwrmax_cf=dtv%XPAR_WRMAX_CF)
  IF (.NOT.any(dtv%LDATA_RGL))      &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,prgl=dtv%XPAR_RGL)
  IF (.NOT.any(dtv%LDATA_CV))       &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pcv=dtv%XPAR_CV)
  IF (.NOT.any(dtv%LDATA_ALBNIR_VEG)) THEN
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,palbnir_veg=dtv%XPAR_ALBNIR_VEG(:,1,:))
    DO jt = 2,dtv%NTIME 
      dtv%XPAR_ALBNIR_VEG(:,jt,:) = dtv%XPAR_ALBNIR_VEG(:,1,:)
    ENDDO
  ENDIF
  IF (.NOT.any(dtv%LDATA_ALBVIS_VEG)) THEN
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,palbvis_veg=dtv%XPAR_ALBVIS_VEG(:,1,:))
    DO jt = 2,dtv%NTIME 
      dtv%XPAR_ALBVIS_VEG(:,jt,:) = dtv%XPAR_ALBVIS_VEG(:,1,:)
    ENDDO
  ENDIF    
  IF (.NOT.any(dtv%LDATA_ALBUV_VEG)) THEN
    CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,palbuv_veg=dtv%XPAR_ALBUV_VEG(:,1,:))
    DO jt = 2,dtv%NTIME 
      dtv%XPAR_ALBUV_VEG(:,jt,:) = dtv%XPAR_ALBUV_VEG(:,1,:)
    ENDDO
  ENDIF      
  IF (isize_lmeb_patch>0)  THEN
    IF (.NOT.any(dtv%LDATA_BSLAI)) CALL ini_data_param(pbslai=dtv%XPAR_BSLAI)
  ENDIF
  IF (io%CPHOTO /= 'NON')  THEN
    IF (.NOT.any(dtv%LDATA_GMES))   &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pgmes_st=dtv%XPAR_GMES)
    IF (.NOT.any(dtv%LDATA_BSLAI))  &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pbslai_st=dtv%XPAR_BSLAI)
    IF (.NOT.any(dtv%LDATA_SEFOLD)) &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,psefold_st=dtv%XPAR_SEFOLD)
    IF (.NOT.any(dtv%LDATA_GC))     &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pgc_st=dtv%XPAR_GC)
  ELSE
    IF (.NOT.any(dtv%LDATA_GMES))   &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pgmes=dtv%XPAR_GMES)
    IF (.NOT.any(dtv%LDATA_BSLAI))  &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pbslai=dtv%XPAR_BSLAI)
    IF (.NOT.any(dtv%LDATA_SEFOLD)) &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,psefold=dtv%XPAR_SEFOLD)
    IF (.NOT.any(dtv%LDATA_GC))     &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pgc=dtv%XPAR_GC)
  ENDIF
  IF (.NOT.any(dtv%LDATA_LAIMIN))    &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,plaimin_out=dtv%XPAR_LAIMIN)
  IF (.NOT.any(dtv%LDATA_F2I))       &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pf2i=dtv%XPAR_F2I)
  IF (.NOT.any(dtv%LDATA_CE_NITRO))  &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pce_nitro=dtv%XPAR_CE_NITRO)
  IF (.NOT.any(dtv%LDATA_CF_NITRO))  &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pcf_nitro=dtv%XPAR_CF_NITRO)
  IF (.NOT.any(dtv%LDATA_CNA_NITRO)) &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pcna_nitro=dtv%XPAR_CNA_NITRO)
  !
  dtv%LDATA_GAMMA(:)     =.true.
  dtv%LDATA_WRMAX_CF(:)  =.true.
  dtv%LDATA_RGL(:)       =.true.
  dtv%LDATA_CV(:)        =.true.
  dtv%LDATA_ALBNIR_VEG(:)=.true.
  dtv%LDATA_ALBVIS_VEG(:)=.true.
  dtv%LDATA_ALBUV_VEG(:) =.true.
  dtv%LDATA_GMES(:)      =.true.
  dtv%LDATA_BSLAI(:)     =.true.
  dtv%LDATA_SEFOLD(:)    =.true.
  dtv%LDATA_GC(:)        =.true.
  dtv%LDATA_LAIMIN(:)    =.true.
  dtv%LDATA_F2I(:)       =.true.
  dtv%LDATA_CE_NITRO(:)  =.true.
  dtv%LDATA_CF_NITRO(:)  =.true.
  dtv%LDATA_CNA_NITRO(:) =.true.
  !
  dtv%LDATA_STRESS(:)    =.true.
  !
  ALLOCATE(dtv%LPAR_STRESS(kdim,nvegtype))  
  dtv%LPAR_STRESS(:,:) = .true.
  IF(io%LAGRI_TO_GRASS)THEN
    DO jveg=1,nvegtype
      IF(xstress_noagri(jveg)<1.) dtv%LPAR_STRESS(:,jveg) = .false.
    ENDDO 
  ELSE
    DO jveg=1,nvegtype
      IF(xstress(jveg)<1.) dtv%LPAR_STRESS(:,jveg) = .false.
    ENDDO
  ENDIF
  !
  !
  IF (.NOT.any(dtv%LDATA_IRRIG)) THEN
    ALLOCATE(dtv%XPAR_IRRIG     (kdim,dtv%NTIME,nvegtype))
    CALL av_pgd(dtco, dtv%XPAR_IRRIG(:,kdecade2,:),pcover,xdata_irrig(:,:),yveg,'ARI',ocover,kdecade=kdecade)
    dtv%LDATA_IRRIG(:)=.true.
  ENDIF
  !
  IF (.NOT.any(dtv%LDATA_WATSUP)) THEN
    ALLOCATE(dtv%XPAR_WATSUP     (kdim,dtv%NTIME,nvegtype))
    CALL av_pgd(dtco, dtv%XPAR_WATSUP(:,kdecade2,:),pcover,xdata_watsup(:,:),yveg,'ARI',ocover,kdecade=kdecade)
    dtv%LDATA_WATSUP(:)=.true.
  ENDIF
  !
  ALLOCATE(tpwork(kdim,nvegtype))
  !
  IF (.NOT.any(dtv%LDATA_SEED_M).OR..NOT.any(dtv%LDATA_SEED_D)) THEN
    ALLOCATE(dtv%XPAR_SEED_M(kdim,nvegtype))
    ALLOCATE(dtv%XPAR_SEED_D(kdim,nvegtype))
    CALL av_pgd(tpwork(:,:),pcover,tdata_seed(:,:),yveg,'MAJ',ocover,kdecade=kdecade)
    dtv%XPAR_SEED_M(:,:) = float(tpwork(:,:)%TDATE%MONTH)
    dtv%XPAR_SEED_D(:,:) = float(tpwork(:,:)%TDATE%DAY)
    dtv%LDATA_SEED_M(:)=.true.
    dtv%LDATA_SEED_D(:)=.true.
  ENDIF
  !
  IF (.NOT.any(dtv%LDATA_REAP_M).OR..NOT.any(dtv%LDATA_REAP_D)) THEN
    ALLOCATE(dtv%XPAR_REAP_M(kdim,nvegtype))
    ALLOCATE(dtv%XPAR_REAP_D(kdim,nvegtype))
    CALL av_pgd(tpwork(:,:),pcover,tdata_reap(:,:),yveg,'MAJ',ocover,kdecade=kdecade)
    dtv%XPAR_REAP_M(:,:) = float(tpwork(:,:)%TDATE%MONTH)
    dtv%XPAR_REAP_D(:,:) = float(tpwork(:,:)%TDATE%DAY)
    dtv%LDATA_REAP_M(:)=.true.
    dtv%LDATA_REAP_D(:)=.true.
  ENDIF
  !
  DEALLOCATE(tpwork)  
!
! MEB stuff
!
  IF (isize_lmeb_patch>0)  THEN

!Z0LITTER
    IF (.NOT.any(dtv%LDATA_Z0LITTER)) THEN
      ALLOCATE(dtv%XPAR_Z0LITTER(kdim,dtv%NTIME,nvegtype))
      CALL ini_data_param( pz0litter=dtv%XPAR_Z0LITTER)
      dtv%LDATA_Z0LITTER(:)=.true.
    ENDIF
!
!H_VEG
    IF (.NOT.any(dtv%LDATA_H_VEG) .AND. any(dtv%LDATA_LAI) .AND. any(dtv%LDATA_H_TREE)) THEN
      ALLOCATE(dtv%XPAR_H_VEG(kdim,dtv%NTIME,nvegtype))
      CALL ini_data_param(ph_veg=dtv%XPAR_H_VEG,plai=dtv%XPAR_LAI,  &
                          ph_tree=dtv%XPAR_H_TREE)
      dtv%LDATA_H_VEG(:)=.true.
    ENDIF
!
!GNDLITTER
    IF (.NOT.any(dtv%LDATA_GNDLITTER) ) THEN
      ALLOCATE(dtv%XPAR_GNDLITTER(kdim,dtv%NTIME,nvegtype))
      CALL ini_data_param(pgndlitter=dtv%XPAR_GNDLITTER)
      dtv%LDATA_GNDLITTER(:)=.true.
    ENDIF
    !
  ENDIF
  !
ENDIF
!
!
IF (dtv%LDATA_VEGTYPE) THEN
  IF (.NOT.any(dtv%LDATA_Z0_O_Z0H)) ALLOCATE(dtv%XPAR_Z0_O_Z0H  (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_DMAX)) ALLOCATE(dtv%XPAR_DMAX      (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_RE25)) ALLOCATE(dtv%XPAR_RE25      (kdim,nvegtype))
  IF (.NOT.any(dtv%LDATA_Z0_O_Z0H)) &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pz0_o_z0h=dtv%XPAR_Z0_O_Z0H)
  IF (io%CPHOTO /= 'NON')  THEN
    IF (.NOT.any(dtv%LDATA_DMAX)) &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pdmax_st=dtv%XPAR_DMAX)
  ELSE
    IF (.NOT.any(dtv%LDATA_DMAX)) &
            CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pdmax=dtv%XPAR_DMAX)
  ENDIF
  IF (.NOT.any(dtv%LDATA_RE25)) &
          CALL ini_data_param(oagri_to_grass=io%LAGRI_TO_GRASS,pre25=dtv%XPAR_RE25)
  !
  dtv%LDATA_Z0_O_Z0H(:)=.true.
  dtv%LDATA_DMAX(:)    =.true.
  dtv%LDATA_RE25(:)    =.true.
ENDIF
!
IF (lhook) CALL dr_hook('INIT_ISBA_MIXPAR',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE init_isba_mixpar