get_near_meshes_cartesian.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_near_meshes_cartesian(KGRID_PAR,KL,PGRID_PAR,KNEAR_NBR,KNEAR)
!     ##############################################################
!
!!**** *GET_NEAR_MESHES_CARTESIAN* get the near grid mesh indices
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE mode_gridtype_cartesian
!
USE modd_surfex_mpi, ONLY : nindex, nrank, nnum
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
INTEGER,                         INTENT(IN)    :: KGRID_PAR ! size of PGRID_PAR
INTEGER,                         INTENT(IN)    :: KL        ! number of points
INTEGER,                         INTENT(IN)    :: KNEAR_NBR ! number of nearest points wanted
REAL,    DIMENSION(KGRID_PAR),   INTENT(IN)    :: PGRID_PAR ! grid parameters
INTEGER, DIMENSION(:,:),POINTER :: KNEAR     ! near mesh indices
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER                            :: IIMAX, IJMAX
INTEGER                            :: JI, JJ
INTEGER                            :: JX, JY
INTEGER                            :: JL
INTEGER                            :: IDIST
INTEGER                            :: ICOUNT
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_NEAR_MESHES_CARTESIAN',0,zhook_handle)
 CALL get_gridtype_cartesian(pgrid_par,kimax=iimax,kjmax=ijmax)
!
knear(:,:) = 0
!
idist = int(sqrt(float(knear_nbr)))
!
IF (iimax*ijmax==kl) THEN
  DO jj=1,ijmax
    DO ji=1,iimax
      icount = 0
      jl = ji + iimax * (jj-1)
      IF (nindex(jl)==nrank) THEN
        knear(nnum(jl),:) = 0      
        DO jx=-(idist-1)/2,idist/2
          DO jy=-(idist-1)/2,idist/2
            IF (ji+jx>0 .AND. ji+jx<iimax+1 .AND. jj+jy>0 .AND. jj+jy<ijmax+1) THEN
              icount = icount + 1
              knear(nnum(jl),icount) = (ji+jx) + iimax * (jj+jy-1)
            END IF
          END DO
        END DO
      ENDIF
    ENDDO
  END DO
END IF
IF (lhook) CALL dr_hook('GET_NEAR_MESHES_CARTESIAN',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_near_meshes_cartesian