ch_emission_fluxn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE ch_emission_flux_n (DTCO, U, CHE, SV, CHU, HPROGRAM,PSIMTIME,PSFSV, PRHOA, PTSTEP, KNBTS_MAX)
!     ######################################################################
!!
!!***  *CH_EMISSION_FLUX_n* - 
!!
!!    PURPOSE
!!    -------
!!      Return a time-dependent emission flux based on tabulated values
!!
!!**  METHOD
!!    ------
!!
!!    AUTHOR
!!    ------
!!    D. Gazen
!!
!!    MODIFICATIONS
!!    -------------
!!    Original 08/02/00
!!    C. Mari  30/10/00 call to MODD_TYPE_EFUTIL and MODD_CST
!!    D.Gazen  01/12/03  change emissions handling for surf. externalization
!!    P.Tulet  01/01/04  change emission conversion factor
!!    P.Tulet  01/01/05  add dust, orilam
!!    M.Leriche    2015  suppress ZDEPOT
!!    M.Moge    01/2016  using READ_SURF_FIELD2D for 2D surfex fields reads
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_ch_emis_field_n, ONLY : ch_emis_field_t
USE modd_sv_n, ONLY : sv_t
USE modd_ch_surf_n, ONLY : ch_surf_t
!
USE modd_type_efutil,      ONLY: emissvar_t, pronosvar_t
USE modd_csts,             ONLY: ndaysec
!
USE modi_read_surf_field2d
USE modi_init_io_surf_n
USE modi_end_io_surf_n
USE modi_get_luout
!UPG*AERO1
USE modd_chs_aerosol, ONLY: lch_aero_flux
USE modi_ch_aer_emission
!UPG*AERO1
!!
!------------------------------------------------------------------------------
!
!*       0.   DECLARATIONS
!        -----------------
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1  declaration of arguments
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(ch_emis_field_t), INTENT(INOUT) :: CHE
TYPE(sv_t), INTENT(INOUT) :: SV
TYPE(ch_surf_t), INTENT(INOUT) :: CHU
!
 CHARACTER(LEN=6),   INTENT(IN)  :: HPROGRAM    ! program calling surf. schemes
REAL,               INTENT(IN)  :: PSIMTIME    ! time of simulation in sec UTC
                                               ! (counting from midnight of
                                               ! the current day)
REAL,DIMENSION(:,:),  INTENT(INOUT) :: PSFSV   ! emission flux in ppp*m/s
REAL, DIMENSION(:),   INTENT(IN)    :: PRHOA     ! air density (kg/m3)
REAL,                 INTENT(IN)    :: PTSTEP    ! atmospheric time-step                 (s)
INTEGER,              INTENT(IN)    :: KNBTS_MAX !max size of TEMISS%NETIMES

!
!*       0.2  declaration of local variables
!
INTEGER       :: IVERB   ! verbosity level
INTEGER       :: KSIZE1D ! 1D size = X*Y physical domain 
INTEGER       :: JI      ! loop control
REAL          :: ZALPHA  ! interpolation weight
!
INTEGER :: INBTS       ! Number of emission times for a species
INTEGER :: ITIM1,ITIM2 ! first/last time for interpolation
INTEGER :: INDX1,INDX2 ! first/next index for data interpolation
INTEGER :: ISIMTIME, ITPERIOD
 CHARACTER (LEN=16)  :: YRECFM          ! LFI article name
TYPE(pronosvar_t),POINTER :: CURPRONOS !Current pronostic variable
!
!*       0.3  declaration of saved local variables
!
 CHARACTER(LEN=6), DIMENSION(:), POINTER :: CNAMES
REAL,DIMENSION(SIZE(PSFSV,1),KNBTS_MAX)     :: ZWORK ! temporary array for reading data
REAL,DIMENSION(SIZE(PSFSV,1),SIZE(PSFSV,2)) :: ZEMIS ! interpolated in time emission flux
REAL,DIMENSION(SIZE(PSFSV,1))               :: ZFCO  ! CO flux
INTEGER                          :: INEQ  ! number of chemical var
                                          !(=NEQ (chimie gaz) + NSV_AER (chimie aerosol)
INTEGER                          :: IWS   ! window size
INTEGER                          :: IRESP ! return code for I/O
INTEGER                          :: ILUOUT ! Outputlisting unit
LOGICAL                          :: LIOINIT ! True if I/O init done
INTEGER                          :: JW
INTEGER                          :: ITIME
LOGICAL                          :: GCO = .false. ! switch if CO emission are available
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!------------------------------------------------------------------------------
!
!*    EXECUTABLE STATEMENTS
!     ---------------------
!
IF (lhook) CALL dr_hook('CH_EMISSION_FLUX_N',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
lioinit = .false.
iverb   = 5
ksize1d = SIZE(psfsv,1)
ineq    = SIZE(psfsv,2)
!
!------------------------------------------------------------------------------
!
!*    3.  INTERPOLATE SURFACE FLUXES IN TIME IF NEEDED
!     ------------------------------------------------
!
IF (che%XTIME_SIMUL == 0.) THEN
   che%XTIME_SIMUL = psimtime
ELSE
   che%XTIME_SIMUL = che%XTIME_SIMUL + ptstep
END IF

IF (iverb >= 5) WRITE(iluout,*) '******** CH_EMISSION_FLUX  ********'
DO ji=1,SIZE(che%TSEMISS)
! Simulation time (counting from midnight) is saved
  isimtime = che%XTIME_SIMUL
!
  inbts = SIZE(che%TSEMISS(ji)%NETIMES) ! 
  iws   = che%TSEMISS(ji)%NWS           ! Window Size for I/O
  indx1 = che%TSEMISS(ji)%NDX           ! Current data index
!
  IF (inbts == 1) THEN
!   Time Constant Flux
!   XFWORK already points on data (see ch_buildemiss.f90)
    IF (iverb >= 6) THEN
      WRITE(iluout,*) 'NO interpolation for ',trim(che%TSEMISS(ji)%CNAME)
      IF (iverb >= 10 ) WRITE(iluout,*) che%TSEMISS(ji)%XFWORK
    END IF
  ELSE
    IF (iverb >= 6) THEN
      WRITE(iluout,*) 'Interpolation (T =',isimtime,') : ',che%TSEMISS(ji)%CNAME
    END IF
    IF (isimtime < che%TSEMISS(ji)%NETIMES(1)) THEN
!     Tsim < T(1)=Tmin should not happen but who knows ?
      che%TSEMISS(ji)%NTX = 1
    ELSE
!     Check for periodicity when ISIMTIME is beyond last emission time
!     and probably correct ISIMTIME
      IF (isimtime > che%TSEMISS(ji)%NETIMES(inbts)) THEN 
!       Tsim > T(INBTS)=Tmax
        itperiod = (1+(che%TSEMISS(ji)%NETIMES(inbts)-&
                che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NPX))/ndaysec)*ndaysec  
        isimtime = modulo(isimtime-che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NPX),itperiod)+&
                che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NPX)  
        IF (iverb >= 6) THEN
          WRITE(iluout,*) '  ITPERIOD = ', itperiod
          WRITE(iluout,*) '  ISIMTIME modifie = ', isimtime
        END IF
        IF (che%TSEMISS(ji)%NTX == inbts .AND. isimtime<che%TSEMISS(ji)%NETIMES(inbts)) THEN
!         Update time index NTX 
          che%TSEMISS(ji)%NTX = che%TSEMISS(ji)%NPX
!         Increment data index NDX : NDX correction will occur later
!                                    to assure 1 <= NDX <= IWS
          indx1 = indx1 + 1
        END IF
      END IF
!
!     search NTX such that : ETIMES(NTX) < ISIMTIME <= ETIMES(NTX+1)
!     and make NDX follow NTX : NDX correction will occur later
!                               to assure 1 <= NDX <= IWS
      DO WHILE (che%TSEMISS(ji)%NTX < inbts)
        IF (isimtime >= che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NTX+1)) THEN
          che%TSEMISS(ji)%NTX = che%TSEMISS(ji)%NTX + 1
          indx1 = indx1 + 1
          indx2 = indx1 + 1
        ELSE
          EXIT
        END IF
      END DO
    END IF
!
!   Check availability of data within memory Window (XEMISDATA(:,1:IWS))
    IF (indx1 >= iws) THEN
!
!     Data index reached the memory window limits
!
      IF (che%TSEMISS(ji)%LREAD) THEN 
!
!       File must be read to update XEMISDATA array for this species 
!
        IF (.NOT. lioinit) THEN
!         Must be done once before reading
          CALL init_io_surf_n(dtco, u, hprogram,'FULL  ','SURF  ','READ ')
          IF (iverb >= 6) WRITE(iluout,*) 'INIT des I/O DONE.'
          lioinit=.true.
        END IF
        yrecfm='E_'//trim(che%TSEMISS(ji)%CNAME)
        IF (iverb >= 6)&
               WRITE (iluout,*) 'READ emission :',trim(yrecfm),&
               ', SIZE(ZWORK)=',SIZE(zwork,1),inbts 
        CALL read_surf_field2d(hprogram,zwork(:,1:inbts),yrecfm)
!
! Correction : Replace 999. with 0. value in the Emission FLUX
        WHERE(zwork(:,1:inbts) == 999.)
          zwork(:,1:inbts) = 0. 
        END WHERE
        WHERE(zwork(:,1:inbts) == 1.e20)
          zwork(:,1:inbts) = 0. 
        END WHERE
        DO itime=1,inbts
        zwork(:,itime) = zwork(:,itime)*chu%XCONVERSION(:)
        END DO
!
!       
        IF ((che%TSEMISS(ji)%NTX+iws-1) > inbts) THEN
!
!         ===== Periodic CASE =====
!
          IF (iverb >= 6)&
                 WRITE (iluout,*) 'Periodic CASE : NPX =',che%TSEMISS(ji)%NPX  
          IF (iws <  (inbts-che%TSEMISS(ji)%NPX+1)) THEN
!           Window size is smaller then number of periodical times
!
!           example : IWS=5, NPX=2, INBTS=11, NTX=9
!                               NTX       NPX
!                                |         |
!           time index :      ...9 10 11 # 2 3 4...11 #
!       old data index :[1 2 3 4 5] 
!       new data index :        [1  2  3   4 5]
!                                |  
!                               NDX    
!
            che%TSEMISS(ji)%XEMISDATA(:,1:inbts-che%TSEMISS(ji)%NTX+1) = &
                   zwork(:,che%TSEMISS(ji)%NTX:inbts)  
!
            IF (iverb >= 6) THEN
              WRITE(iluout,*) 'Window SIZE smaller than INBTS !'
              WRITE(iluout,*) 'Window index, Time index'
              DO jw=1,inbts-che%TSEMISS(ji)%NTX+1
                WRITE(iluout,*) jw,che%TSEMISS(ji)%NTX+jw-1
              END DO
            END IF
!
            che%TSEMISS(ji)%XEMISDATA(:,inbts-che%TSEMISS(ji)%NTX+2:iws) = &
                   zwork(:,che%TSEMISS(ji)%NPX:che%TSEMISS(ji)%NPX+iws-inbts+che%TSEMISS(ji)%NTX-2)  
!
            IF (iverb >= 6) THEN
              DO jw=inbts-che%TSEMISS(ji)%NTX+2,iws
                WRITE(iluout,*) jw,che%TSEMISS(ji)%NPX+jw-(inbts-che%TSEMISS(ji)%NTX+2)
              END DO
            END IF
            indx1 = 1
            indx2 = 2
          ELSE
!           Window size may get smaller AND it will be the last reading
!
!           example : IWS=6, NPX=7, INBTS=11, NTX=9
!
!                         NTX       NPX NTX
!                          |         |   |
!           time index: ...9 10 11 # 7 8 9 10 11 #
!       old data index: ...6]
!       new data index:             [1 2 3  4  5]
!                                        |
!                                       NDX=NTX-NPX+1
!
            iws = inbts-che%TSEMISS(ji)%NPX+1
            che%TSEMISS(ji)%NWS = iws
            che%TSEMISS(ji)%XEMISDATA(:,1:iws) = zwork(:,che%TSEMISS(ji)%NPX:inbts)
            IF (iverb >= 6) THEN
              WRITE(iluout,*) 'Window SIZE equal or greater than INBTS !'
              WRITE(iluout,*) 'Window index, Time index'
              DO jw=1,iws
                WRITE(iluout,*) jw,che%TSEMISS(ji)%NPX+jw-1
              END DO
            END IF
            indx1 = che%TSEMISS(ji)%NTX-che%TSEMISS(ji)%NPX+1
            indx2 = mod((indx1+1),iws)
            che%TSEMISS(ji)%LREAD = .false. ! no more reading
          END IF
        ELSE
!
!         ===== NON periodic (normal) CASE =====
!
! example : with IWS=5, the window moves forward
!                             NTX
!                              | 
!         time index : 1 2 3 4 5 6 7 8 9 10 11 ... INBTS # 
!     old data index :[1 2 3 4 5] 
!     new data index :        [1 2 3 4 5] 
!                              |
!                             NDX
!
          che%TSEMISS(ji)%XEMISDATA(:,1:iws) = zwork(:,che%TSEMISS(ji)%NTX:che%TSEMISS(ji)%NTX+iws-1)
          IF (iverb >= 6) THEN
            WRITE(iluout,*) 'Window index, Time index'
            DO jw=1,iws
              WRITE(iluout,*) jw,che%TSEMISS(ji)%NTX+jw-1
            END DO
          END IF
          indx1 = 1
          indx2 = 2
        END IF
      ELSE
!       Data is already in memory because window size is sufficient 
!       to hold INBTS emission times => simply update NDX according to NTX
!       
        IF (iws==inbts) THEN 
!
!         'Window size' = 'Nb emis times' at INIT (ch_init_emission)
!         so NDX must be set equal to NTX (the window does not move)
! example :
!                         NPX    NTX
!                          |      | 
!         time index :  1  2  3  ... INBTS
!         data index : [1  2  3  ... INBTS]
!                                 |
!                                NDX

          indx1 = che%TSEMISS(ji)%NTX
          indx2 = indx1+1
          IF (indx2 > iws) indx2=che%TSEMISS(ji)%NPX
        ELSE
!          
!         Windows size changed during periodic case
!         NDX must be equal to NTX - NPX + 1
!         (the window does not move)
! example :
!                                NTX
!                                 | 
!         time index : NPX NPX+1 NPX+2 ... INBTS
!         data index : [1    2    3    ...   IWS]
!                                 |
!                                NDX
          indx1 = che%TSEMISS(ji)%NTX-che%TSEMISS(ji)%NPX+1
          indx2 = mod((indx1+1),iws)
        END IF
      END IF
    ELSE ! (INDX1 < IWS)
      indx2 = indx1+1
    END IF
!
!   Don't forget to update NDX with new value INDX1
    che%TSEMISS(ji)%NDX = indx1
!
!   Compute both times for interpolation
    IF (che%TSEMISS(ji)%NTX < inbts) THEN 
      itim1 = che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NTX)
      itim2 = che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NTX+1)
    ELSE
      itim1 = che%TSEMISS(ji)%NETIMES(inbts)
      itim2 = che%TSEMISS(ji)%NETIMES(che%TSEMISS(ji)%NPX)+itperiod
    END IF
!
! Interpolate variables in time -> update XFWORK
!
!
!  time       :  ITIM1...Tsim...ITIM2
!                  |              |  
!  data index :  INDX1          INDX2
!
!
    zalpha = (REAL(ISIMTIME) - ITIM1) / (ITIM2-ITIM1)
    che%TSEMISS(ji)%XFWORK(:) = zalpha*che%TSEMISS(ji)%XEMISDATA(:,indx2) +&
            (1.-zalpha)*che%TSEMISS(ji)%XEMISDATA(:,indx1)  
    IF (iverb >= 6) THEN
      WRITE(iluout,*) '  Current time INDEX : ',che%TSEMISS(ji)%NTX
      WRITE(iluout,*) '  TIME : ',isimtime, ' (',itim1,',',itim2,')'
      WRITE(iluout,*) '  Window size : ',che%TSEMISS(ji)%NWS
      WRITE(iluout,*) '  Current data INDEX : ',indx1,indx2
      IF (iverb >= 10) WRITE(iluout,*) '  FLUX : ',che%TSEMISS(ji)%XFWORK
    END IF
  END IF
END DO
! 
! Agregation : flux computation
!
zemis(:,:) = 0.
!
! Point on head of Pronostic variable list
! to cover the entire list.
IF (sv%NSV_AEREND > 0) THEN
CNAMES=>SV%CSV(SV%NSV_CHSBEG:SV%NSV_AEREND)
ELSE
CNAMES=>SV%CSV(SV%NSV_CHSBEG:SV%NSV_CHSEND)
END IF
CURPRONOS=>CHE%TSPRONOSLIST
DO WHILE(ASSOCIATED(curpronos))
  IF (curpronos%NAMINDEX > ineq) THEN
    WRITE(iluout,*) 'FATAL ERROR in CH_EMISSION_FLUXN : SIZE(ZEMIS,2) =',&
           ineq,', INDEX bugge =',curpronos%NAMINDEX  
    CALL abor1_sfx('CH_EMISSION_FLUXN: FATAL ERROR')
  END IF
  
  zemis(:,curpronos%NAMINDEX) = 0.
!
! Loop on the number of agreg. coeff.
  DO ji=1,curpronos%NBCOEFF
!   Compute agregated flux    
    zemis(:,curpronos%NAMINDEX) = zemis(:,curpronos%NAMINDEX)+&
            curpronos%XCOEFF(ji)*che%TSEMISS(curpronos%NEFINDEX(ji))%XFWORK(:)  
  END DO

  IF (iverb >= 6) THEN
    WRITE(iluout,*) 'Agregation for ',cnames(curpronos%NAMINDEX)
    IF (iverb >= 10) WRITE(iluout,*) 'ZEMIS = ',zemis(:,curpronos%NAMINDEX)
  END IF
  IF ((cnames(curpronos%NAMINDEX) == "CO") .AND. any(zemis(:,curpronos%NAMINDEX).GT.0.)) THEN
  zfco(:) = zemis(:,curpronos%NAMINDEX)
  gco = .true.
  END IF

  curpronos=>curpronos%NEXT
!
END DO
!
IF ((lch_aero_flux).AND.(sv%NSV_AERBEG > 0)) THEN
  IF (gco) THEN
    CALL ch_aer_emission(zemis, prhoa, sv%CSV, sv%NSV_CHSBEG, pfco=zfco)
  ELSE
    CALL ch_aer_emission(zemis, prhoa, sv%CSV, sv%NSV_CHSBEG)
  ENDIF
END IF
!
psfsv(:,:) = psfsv(:,:) + zemis(:,:)
!
IF (lioinit) CALL end_io_surf_n(hprogram)
!
IF (iverb >= 6) WRITE(iluout,*) '******** END CH_EMISSION_FLUX  ********'
IF (lhook) CALL dr_hook('CH_EMISSION_FLUX_N',1,zhook_handle)
!
END SUBROUTINE ch_emission_flux_n