bld_occ_calendar.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#####################################################################################
SUBROUTINE bld_occ_calendar(TPTIME, PTSUN, T, B, PQIN_FRAC, PTCOOL_TARGET, PTHEAT_TARGET, PQIN)
!#####################################################################################
!! **** BLD_OCC_CALENDAR *
!!
!!  PURPOSE
!!  -------
!! BLD_OCC_CALENDAR defines the parameters relevant for BEM (TCOOL_TARGET, THEAT_TARGET and QIN)
!! depending on the building use type (hence the DOW and local French TOD) * based on MUSCADE scenarii *
!!
!! AUTHOR
!! ------
!! C. de Munck     *Météo-France*
!! 
!! MODIFICATIONS
!! -------------
!! Original  02/2013
!
USE modd_teb_n, ONLY : teb_t
USE modd_bem_n, ONLY : bem_t
!
USE modd_type_date_surf, ONLY : date_time
!
USE modd_csts,         ONLY : xtt
!
USE modi_day_of_week
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!! 1. declaration of arguments
!
TYPE(date_time), INTENT(INOUT) :: TPTIME
REAL,   DIMENSION(:) , INTENT(IN) :: PTSUN         ! current solar time  (s, UTC)
!
TYPE(teb_t), INTENT(INOUT) :: T
TYPE(bem_t), INTENT(INOUT) :: B
!
REAL,                INTENT(IN)  :: PQIN_FRAC        ! Fraction of internal gains when unoccupied (-)
!
REAL, DIMENSION(:) , INTENT(OUT)  :: PTCOOL_TARGET ! Cooling setpoint of HVAC system [K]
REAL, DIMENSION(:) , INTENT(OUT)  :: PTHEAT_TARGET ! Heating setpoint of HVAC system [K]
REAL, DIMENSION(:) , INTENT(OUT)  :: PQIN          ! Internal heat gains [W m-2(floor)]
!
!! 2. declaration of local variables
!
 CHARACTER(LEN = 6)                :: CTIME         ! Local time scheme (winter or summer time)
INTEGER                           :: JDOW          ! day of week
INTEGER                           :: JJ
!
REAL, DIMENSION(SIZE(PQIN))       :: ZTOD_BEG      ! first Time Of Day that building unoccupied (UTC, s)
REAL, DIMENSION(SIZE(PQIN))       :: ZTOD_END      ! last Time Of Day that building unoccupied (UTC, s)
REAL, DIMENSION(SIZE(PQIN))       :: ZDT           ! Target temperature change when unoccupied (K)

REAL(KIND=JPRB) :: ZTODOOK_HANDLE
!
IF (lhook) CALL dr_hook('BLD_OCC_CALENDAR',0,ztodook_handle)
!
!--------------------------------------------------------------------------------------
!  3. determine the day of the week and the local time scheme in France
!--------------------------------------------------------------------------------------
!
 CALL day_of_week(tptime%TDATE%YEAR, tptime%TDATE%MONTH, tptime%TDATE%DAY, jdow)
!
ctime = 'WINTER'
IF (tptime%TDATE%MONTH >= 4 .AND. tptime%TDATE%MONTH <= 10) ctime = 'SUMMER'
!
!--------------------------------------------------------------------------------------
!  4. initialisation of parameters
!--------------------------------------------------------------------------------------
!
! Parameters assigned to the occupied values - read in namelist via BATI.csv :
!
ptheat_target(:) = b%XTHEAT_TARGET(:)
!  
ptcool_target(:) = b%XTCOOL_TARGET(:)
! 
pqin(:)          = b%XQIN(:)
!
ztod_beg(:) = 0.
ztod_end(:) = 0.
!
!--------------------------------------------------------------------------------------
!  5. computes beginning and end of unoccupied calendar based on building USE TYPE
!--------------------------------------------------------------------------------------
!
DO jj =1,SIZE(ptsun)
!
 IF (t%XRESIDENTIAL(jj) > 0.5) THEN ! RESIDENTIAL
   !
   IF (jdow >= 2 .AND. jdow <=6) THEN ! week days
     ztod_beg(jj) =  9. * 3600.       !  9 UTC - WINTER time
     ztod_end(jj) = 17. * 3600.       ! 17 UTC - WINTER time
   END IF
   zdt(jj) = t%XDT_RES
   !
 ELSE
   !     
   IF (jdow >= 2 .AND. jdow <=7) THEN ! week days
     ztod_beg(jj) = 17. * 3600.       ! 17 UTC
     ztod_end(jj) =  7. * 3600.       !  7 UTC
   ELSE                               ! week-end
     ztod_beg(jj) =  0. * 3600.       !   0 UTC
     ztod_end(jj) = 24. * 3600.       !  24 UTC
   END IF
   zdt(jj) = t%XDT_OFF
   !
 END IF
! adjustment of unoccupied TOD based on time scheme
 IF (ctime == 'SUMMER') THEN
  ztod_beg(jj) = ztod_beg(jj) - 3600.   
  ztod_end(jj) = ztod_end(jj) - 3600.   
 END IF
!
ENDDO
!
!--------------------------------------------------------------------------------------
!  6. modulate BEM input values for unoccupied building calendar
!--------------------------------------------------------------------------------------
!
DO jj =1,SIZE(ptsun)
!
     IF (( (ztod_beg(jj) < ztod_end(jj)) .AND. (ptsun(jj) > ztod_beg(jj) .AND. ptsun(jj) < ztod_end(jj))    )      &
        .OR.                                                                                         &
         ( (ztod_beg(jj) > ztod_end(jj)) .AND. ((ptsun(jj) > 0 .AND. ptsun(jj) < ztod_end(jj)) .OR.            &
                                        (ptsun(jj) > ztod_beg(jj) .AND. ptsun(jj) < 24 * 3600.)))) THEN             
         !
            ptheat_target(jj) = b%XTHEAT_TARGET(jj) - zdt(jj)
            ptcool_target(jj) = b%XTCOOL_TARGET(jj) + zdt(jj)
            pqin(jj) = pqin_frac * pqin(jj)
      ENDIF
!
ENDDO
!
!--------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('BLD_OCC_CALENDAR',1,ztodook_handle)
!
END SUBROUTINE bld_occ_calendar