bem_morpho.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#####################################################################
SUBROUTINE bem_morpho(PBLD, PWALL_O_HOR, PBLD_HEIGHT, PWALL_O_BLD, B)
!#####################################################################
!
!!**** *BEM_MORPHO 
!!
!!    PURPOSE
!!    -------
!! compute morphometric parameter of the building for BEM
!! 
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      G. Pigeon   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2011
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_bem_n, ONLY : bem_t
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:),   INTENT(IN)  :: PBLD         ! Urban horizontal building density
REAL, DIMENSION(:),   INTENT(IN)  :: PWALL_O_HOR  ! Wall to horizontal surface ratio
REAL, DIMENSION(:),   INTENT(IN)  :: PBLD_HEIGHT  ! Average building height [m]
REAL, DIMENSION(:),   INTENT(OUT) :: PWALL_O_BLD  ! wall surface per ground building surface [m2(wall)/m2(bld)]
TYPE(bem_t), INTENT(INOUT) :: B
!
!*      0.2    Declarations of local variables 
!
REAL, DIMENSION(SIZE(PBLD)):: ZF_AUX2       ! Auxiliar view factor
!
!RJ: missing declaration
INTEGER :: JJ
!
!------------------------------------------------------------------------------
!
!*    1.   Verify floor height
!          -------------------
!
DO jj=1,SIZE(pbld)
  IF (b%XFLOOR_HEIGHT(jj) < 2.5) THEN
!    WRITE(ILUOUT,*) 'WARNING: B%XFLOOR_HEIGHT low ',B%XFLOOR_HEIGHT(JJ),' grid mesh number ',JJ
    b%XFLOOR_HEIGHT(jj) = 2.5
  ENDIF
  IF (b%XFLOOR_HEIGHT(jj) > pbld_height(jj)) THEN
!    WRITE(ILUOUT,*) 'WARNING: B%XFLOOR_HEIGHT higher than PBLD_HEIGHT ',B%XFLOOR_HEIGHT(JJ),' grid mesh number ',JJ, &
!                    'set to PBLD_HEIGHT'
    b%XFLOOR_HEIGHT(jj) = pbld_height(jj)
  ENDIF
!
!*    1.   Verify location of HVAC release for very extended buildings
!          -----------------------------------------------------------
!
  IF (pbld(jj) > 0.9999 .AND. b%XF_WASTE_CAN(jj) > 0.) THEN
!    WRITE(ILUOUT,*) 'WARNING: B%XF_WASTE_CAN cannot be higher than 0. while PBLD is 0.9999',B%XF_WASTE_CAN(JJ), &
!                    ' grid mesh number ',JJ,' set to 0.'
    b%XF_WASTE_CAN(jj) = 0.
  ENDIF
END DO
!
!*       1.    floor number, relative surf. and view factors caculation
!              --------------------------------------------------------
!
b%XN_FLOOR(:) = float(nint(pbld_height(:) / b%XFLOOR_HEIGHT(:) ))
pwall_o_bld(:) = pwall_o_hor(:) * (1. - b%XGR(:)) / pbld(:) ! [m2(wall)/m2(bld)]
b%XGLAZ_O_BLD(:) = pwall_o_hor(:) * b%XGR(:)        / pbld(:) ! [m2(win)/m2(bld)]

WHERE(b%XN_FLOOR > 1.5)
   !* more than 1 floor level -> the floor and the roof don't see each other
   !
   !           ROOF
   !  |---------------------|
   !  |                     |
   !  |                     |
   !  |        MASS         |
   !  |---------------------|
   !  |---------------------|
   !  |        MASS         |
   !  |                     |
   !  |                     |
   !  |        FLOOR        |
   !  |---------------------|
   !
   b%XMASS_O_BLD(:) = 2 * (b%XN_FLOOR(:) - 1.)                     ! [m2(mass)/m2(bld)]
   b%XFLOOR_HW_RATIO(:) = pwall_o_hor(:) / b%XN_FLOOR(:) / pbld(:) / 2.
   !
   b%XF_FLOOR_MASS(:) = (b%XFLOOR_HW_RATIO(:)**2 + 1.)**0.5  - b%XFLOOR_HW_RATIO(:)
   b%XF_FLOOR_WALL(:) = (1. - b%XF_FLOOR_MASS(:)) * (1. - b%XGR(:))
   b%XF_FLOOR_WIN (:) = (1. - b%XF_FLOOR_MASS(:)) * b%XGR(:)
   b%XF_FLOOR_ROOF(:) = 0. ! no rad interaction between floor and roof
   !
   zf_aux2(:) = (1. - b%XF_FLOOR_MASS(:)) / b%XFLOOR_HW_RATIO(:)
   !
   b%XF_WALL_FLOOR(:) = zf_aux2(:) / ( 2.*b%XN_FLOOR(:) )
   b%XF_WALL_MASS (:) = b%XF_WALL_FLOOR(:) * (2.*b%XN_FLOOR(:)-2.) 
   b%XF_WALL_WIN  (:) = (1. - zf_aux2(:)) * b%XGR(:)
   !
   b%XF_WIN_FLOOR(:) = b%XF_WALL_FLOOR(:)
   b%XF_WIN_MASS (:) = b%XF_WALL_MASS (:)
   b%XF_WIN_WALL (:) = (1. - b%XF_WIN_FLOOR(:) * 2. - b%XF_WIN_MASS(:) ) * (1. - b%XGR(:))
   b%XF_WIN_WIN  (:) = (1. - b%XF_WIN_FLOOR(:) * 2. - b%XF_WIN_MASS(:) ) * b%XGR(:)
   !
   b%XF_MASS_FLOOR(:) = b%XF_FLOOR_MASS(:) / b%XMASS_O_BLD(:)
   b%XF_MASS_WALL (:) = pwall_o_bld(:) * b%XF_WALL_MASS(:) / b%XMASS_O_BLD(:)
   b%XF_MASS_WIN  (:) = b%XGLAZ_O_BLD (:) * b%XF_WIN_MASS(:)  / b%XMASS_O_BLD(:)
ELSE WHERE
   !* 1 floor level -> no mass view factors ; roof and floor see each other
   !
   !           ROOF
   !  |---------------------|
   !  |                     |
   !  |                     |
   !  |        FLOOR        |
   !  |---------------------|
   !
   b%XMASS_O_BLD(:) = 0.
   b%XFLOOR_HW_RATIO(:) = pwall_o_hor(:) / pbld(:) / 2.
   !
   b%XF_FLOOR_ROOF(:) = (b%XFLOOR_HW_RATIO(:)**2 + 1.)**0.5  - b%XFLOOR_HW_RATIO(:)
   b%XF_FLOOR_MASS(:) = 0.
   b%XF_FLOOR_WALL(:) = (1. - b%XF_FLOOR_ROOF(:)) * (1. - b%XGR(:))
   b%XF_FLOOR_WIN (:) = (1. - b%XF_FLOOR_ROOF(:)) * b%XGR(:)
   !
   zf_aux2(:) = (1. - b%XF_FLOOR_ROOF(:)) / b%XFLOOR_HW_RATIO(:)
   !
   b%XF_WALL_FLOOR(:) = zf_aux2(:) / 2.
   b%XF_WALL_MASS (:) = 0.
   b%XF_WALL_WIN  (:) = (1. - zf_aux2(:)) * b%XGR(:)
   !
   b%XF_WIN_FLOOR(:) = b%XF_WALL_FLOOR(:)
   b%XF_WIN_MASS (:) = 0.
   b%XF_WIN_WALL (:) = (1. - b%XF_WIN_FLOOR(:) * 2. - b%XF_WIN_MASS(:) ) * (1. - b%XGR(:))
   b%XF_WIN_WIN  (:) = (1. - b%XF_WIN_FLOOR(:) * 2. - b%XF_WIN_MASS(:) ) * b%XGR(:)
   !
   b%XF_MASS_FLOOR(:) = 0.
   b%XF_MASS_WALL (:) = 0.
   b%XF_MASS_WIN  (:) = 0.
END WHERE
!
END SUBROUTINE bem_morpho
!-------------------------------------------------------------------------------