average_rad.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average_rad(PFRAC_TILE,                              &
                   PDIR_ALB_TILE, PSCA_ALB_TILE, PEMIS_TILE, PTRAD_TILE,  &
                   PDIR_ALB, PSCA_ALB, PEMIS, PTRAD                       )  
!     #################################################################
!
!
!!****  *AVERAGE_RAD*  
!!
!!    PURPOSE
!!    -------
!      Average the radiative fluxes from the land and water surfaces depending on the
!      fraction of each surface cover type in the mesh area.
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/03/95 
!!      V.Masson    20/03/96  remove abnormal averages and average TS**4 instead
!!                            of TS
!!      (J.Stein)   27/03/96 use only H and LE in the soil scheme
!!      A. Boone    27/11/02 revised to output ALMA variables, and general applications
!       B. decharme 04/2013  Optimization
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:),   INTENT(IN) :: PFRAC_TILE    ! Fraction in a mesh-area of 
!                                                   ! a given surface
REAL, DIMENSION(:,:),   INTENT(IN) :: PEMIS_TILE    ! emissivity
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDIR_ALB_TILE ! direct albedo
REAL, DIMENSION(:,:,:), INTENT(IN) :: PSCA_ALB_TILE ! diffuse albedo
REAL, DIMENSION(:,:),   INTENT(IN) :: PTRAD_TILE    ! surface radiative temp.
REAL, DIMENSION(:),     INTENT(OUT):: PEMIS         ! emissivity
REAL, DIMENSION(:,:),   INTENT(OUT):: PDIR_ALB      ! direct albedo
REAL, DIMENSION(:,:),   INTENT(OUT):: PSCA_ALB      ! diffuse albedo
REAL, DIMENSION(:),     INTENT(OUT):: PTRAD         ! surface radiative temp.
!
!
!*      0.2    declarations of local variables
!
REAL, PARAMETER    :: ZEPS = 1.e-10
!
INTEGER :: INI, INP, INSWB  ! dimenssion
INTEGER :: JI, JP, JSWB     ! loop counter on tiles
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('AVERAGE_RAD',0,zhook_handle)
!
ini   = SIZE(pfrac_tile,1)
inp   = SIZE(pfrac_tile,2)
inswb = SIZE(pdir_alb_tile,2)
!
!       1.     Grid-Box average surface temperatures, radiative properties
!              -----------------------------------------------------------
!
! albedo:
! 
pdir_alb(:,:) = 0.
psca_alb(:,:) = 0.
!
DO jswb = 1,inswb
  DO jp = 1,inp
    DO ji = 1,ini
      pdir_alb(ji,jswb) = pdir_alb(ji,jswb) + pfrac_tile(ji,jp) * pdir_alb_tile(ji,jswb,jp)
      psca_alb(ji,jswb) = psca_alb(ji,jswb) + pfrac_tile(ji,jp) * psca_alb_tile(ji,jswb,jp)
    END DO
  END DO
END DO
!
! emissivity
!
pemis(:)   = 0.
!
DO jp = 1,inp
  DO ji = 1,ini
     pemis(ji) = pemis(ji) + pfrac_tile(ji,jp) * pemis_tile(ji,jp)
  END DO
END DO
!
! radiative surface temperature
!
ptrad(:)   = 0.
!
DO jp = 1, inp
  DO ji = 1,ini
     ptrad(ji) = ptrad(ji) + (ptrad_tile(ji,jp)**4)*pfrac_tile(ji,jp)*pemis_tile(ji,jp)
  END DO
END DO
!
ptrad(:) = ( ptrad(:) / max(pemis(:),zeps) )**0.25
!
IF (lhook) CALL dr_hook('AVERAGE_RAD',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average_rad