average2_cover.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################
      SUBROUTINE average2_cover (U, HPROGRAM)
!     #########################
!
!!**** *AVERAGE2_COVER* computes the cover fractions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surfex_mpi, ONLY : nrank
USE modd_pgdwork,   ONLY : nsize, xsumval, xprec
!
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_pgd_grid,       ONLY : cgrid
!
USE modi_sum_on_all_procs
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=6),  INTENT(IN) :: HPROGRAM      ! Type of program
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(:), ALLOCATABLE :: ZUNITY
!
REAL :: ZINT
INTEGER :: JI, JJ
INTEGER :: JCOV ! loop counter on cover classes
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!----------------------------------------------------------------------------
!
!*    1.     Average values
!            --------------
!
IF (lhook) CALL dr_hook('AVERAGE2_COVER',0,zhook_handle)
ALLOCATE(zunity(SIZE(nsize)))
zunity(:) = 0.
!
ALLOCATE(u%XCOVER(SIZE(nsize,1),SIZE(xsumval,2)))
!
DO jcov=1,SIZE(xsumval,2)
  WHERE (nsize(:,1)/=0)
    u%XCOVER(:,jcov) = xsumval(:,jcov) /nsize(:,1)
    zunity(:)=zunity(:) + u%XCOVER(:,jcov)
  ELSEWHERE
    u%XCOVER(:,jcov) = 0.
  END WHERE
END DO
!
DO jcov=1,SIZE(u%XCOVER,2)
  WHERE (nsize(:,1) /=0 )
    u%XCOVER(:,jcov)=u%XCOVER(:,jcov) / zunity(:)
  END WHERE
END DO
!
DO jj=1,SIZE(u%XCOVER,2)
  DO ji = 1,SIZE(u%XCOVER,1)

    zint = aint(u%XCOVER(ji,jj))
    IF (u%XCOVER(ji,jj)/=zint) THEN
      u%XCOVER(ji,jj) = zint + anint((u%XCOVER(ji,jj)-zint)*xprec)/xprec
    ENDIF

  ENDDO
ENDDO
!
!-------------------------------------------------------------------------------
DEALLOCATE(zunity)
IF (lhook) CALL dr_hook('AVERAGE2_COVER',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE average2_cover